Using awk to calculate a csv but with uneven columns

I need to write a script using the .awk extension to do calculations within a file. Each row contains numbers and a keyword in the last spot dictating whether to add or subtract the numbers within a row. However, since the keywords are not in the same column, I cannot figure out how to parse through this correctly. The table looks like:

1,2,5,7,14,11,51,ADD
1,3,5,SUB
15,13,11,19,ADD
19,13,12,22,SUB
1,5,8,2,0,13,18,22,6,4,7,ADD
11,3,SUB

Any help would be appreciated.

You say you need to write an awk script with the awk extension -- which I take to mean yourscript.awk. awk is fairly simple, as long as you understand Records (lines), Fields (columns) and Rules (the awk commands applied to each line of input -- in the order you write them)

A Rule is contained between outer { ... } within the awk script. There are two special rules BEGIN (runs before the 1st records is processed - for setup, header output, etc..) and the END rule (which runs after the last record is processed (like for outputting total sums of all record values, averages, or processing output after the last record)

In your case you simply need BEGIN to set FS (the Field-Seperator) value to ',' so your fields are spit on ','.

After you set FS, you can use the special variable NF (number of fields) to determine the number of fields in each row (and which field holds "ADD" or "SUB"). If you want to know the current line in the file being processed, the FNR internal variable gives you that info.

With that as a background, you can process your file and either "ADD" all values or "SUB" (substract) all values based on what is in $NF (the $ denotes field-value, e.g. if NF == 3, then $NF is the value of the 3rd field)

It is simpler to loop from the 2nd field on, either adding to, or subtracting from, the first field ($1) to start your calculation for each record. Get the total and output it, repeat for each record in the file, e.g.

#!/bin/awk -f

BEGIN { FS = "," }                        ##  initialize FS to ","

{
  n = $1                                  ##  initialize n to 1st field value
  for (i = 2; i < NF; i++) {              ##  loop fields 2 until NF - 1
    if ($NF == "SUB")                     ##  if $NF is "SUB"
      n -= $i                             ##  subtract current from total
    else if ($NF == "ADD")                ##  otherwise if $NF is "ADD"
      n += $i                             ##  add current to total
  }
  printf "line: %d => % 3d\n", FNR, n     ##  output total
}

Example Use/Output

With your sample data in the file dat/keyword.dat and the script named keyword.awk (and chmod +x keyword.awk to make the file executable), you would do:

$ ./keyword.awk dat/keyword.txt
line: 1 =>  91
line: 2 =>  -7
line: 3 =>  58
line: 4 => -28
line: 5 =>  86
line: 6 =>   8

NOTE: if your ADD or SUB calculations need to be done differently, you can simply adjust the summing logic above as needed.

Let me know if you have questions.