How do I integrate checkboxes and comboboxes with different values and do a basic math statement using only selection if-else-then-elseif statements?

My class homework is asking me to create a form wherein different selected checkboxes and combobox choices will add or subtract from an inputted amount and output the result to a label box when a button is pressed.

My professor tells me that the solution isn't a giant block of nested if statements that show every combination possible, but rather should be a simple solution where if we were to expand the form with two more checkboxes, it should only take a couple of lines to expand it, and not exponentially increase the amount of code we should have.

The professor also states that we are only limited to using if, then, and elseif statements. AND/OR/NOT are allowed. Variables and cases are not allowed. The algorithm has to be very simple.

I have currently tried this code snippet, which currently makes only the last set of if-then statements to work. Everything before that does not work.

    Private Sub btnCalculate_Click(sender As Object, e As EventArgs) Handles btnCalculate.Click
        If cboBuilding.Text = "Crashing Waves" Then
            lblRentDisplay.Text = txtBaseRent.Text + 210
        ElseIf cboBuilding.Text = "SunView" Then
            lblRentDisplay.Text = txtBaseRent.Text + 0
        End If
        If chkLanai.Checked = True Then
            lblRentDisplay.Text = txtBaseRent.Text + 65
        End If
        If chkRooftopDeck.Checked = True Then
            lblRentDisplay.Text = txtBaseRent.Text + 120
        End If
        If chkNonSmoking.Checked = True Then
            lblRentDisplay.Text = txtBaseRent.Text - 25
        Else
            lblRentDisplay.Text = txtBaseRent.Text + 0
        End If

I have even nested the checkbox statements under each of the combo box statements and have had no luck.

Even creating a giant block of every combination yielded me no results.

First of all, turn on Option Strict (or Option Infer)! I know it seems like extra work at first, but this really will make you faster and more accurate as you get used to it.

That out of the way, all controls have a Tag property^*. Use this property to store the rent adjustment value for each control. Then do this:

Private Sub btnCalculate_Click(sender As Object, e As EventArgs) Handles btnCalculate.Click
    Static perkMap As New Dictionary(Of String, Integer) From {
           { "Crashing Waves", 120},
           { "SunView", 0}
        }

    Dim perkPrice As Integer = 0
    If perkMap.ContainsKey(cboBuilding.Text) Then
        perkPrice = perkMap(cboBuilding.Text)
    End If

    Dim adjustmentPrice As Integer = 
        Me.Controls.OfType(Of CheckBox)().
            Where(Function(cb) cb.Checked).
            Select(Function(cb) CInt(cb.Tag)).
            Sum()

    lblRentDisplay.Text = (CInt(txtBaseRent.Text) + perkPrice + adjustmentPrice).ToString()
End Sub

But given this looks like the type of homework where you haven't learned how to use those lambda expression methods yet, you might prefer to write it like this:

Private Sub btnCalculate_Click(sender As Object, e As EventArgs) Handles btnCalculate.Click
    Static perkMap As New Dictionary(Of String, Integer) From {
           { "Crashing Waves", 120},
           { "SunView", 0}
        }

    Dim perkPrice As Integer = 0
    If perkMap.ContainsKey(cboBuilding.Text) Then
        perkPrice = perkMap(cboBuilding.Text)
    End If

    Dim adjustmentPrice As Integer = 0
    Dim checkboxes = Me.Controls.OfType(Of CheckBox)()
    For Each box as CheckBox In checkboxes
        If box.Checked Then
           adjustmentPrice += CInt(box.Tag)
        End If
    Next

    lblRentDisplay.Text = (CInt(txtBaseRent.Text) + perkPrice + adjustmentPrice).ToString()
End Sub

Separate from the Tag property you could also instead a Dictionary similar to perkMap to store the rent adjustments, where you lookup the value based on each CheckBox's Name property.

If you haven't encountered generics yet and aren't comfortable using OfType(Of T), you can make an array and add the checkboxes to it at the beginning of the method. Then the only code adjustment needed when you add a checkbox is to also add it to the array.

Finally, it's possible you have other checkboxes on the form that are not part of this group. Of course you don't want to use those here. In that situation, put all these checkboxes in a common container control, like a Panel, GroupBox, or FlowLayoutPanel. Then you can use that parent instead of Me when calling the OfType(Of T) method.

_{* Aside: I'd love to see an updated WinForms with a set of controls using a generic type for this property.}

You're explicitly calculating each modification by starting over from the base value every time. Only the first calculation should use the "base rent". Each subsequent one should simply add or remove from what is already in lblRentDisplay:

If cboBuilding.Text = "Crashing Waves" Then
    lblRentDisplay.Text = txtBaseRent.Text + 210
End If
If chkLanai.Checked = True Then
    lblRentDisplay.Text = lblRentDisplay.Text + 65
End If
If chkRooftopDeck.Checked = True Then
    lblRentDisplay.Text = lblRentDisplay.Text + 120
End If
If chkNonSmoking.Checked = True Then
    lblRentDisplay.Text = lblRentDisplay.Text - 25
End If

*Caveat, using the .Text property to do math should be HIGHLY DISCOURAGED! Ideally you'd declare some class level variables that hold NUMERIC values and do math with those instead. Then simply update the label at the end with the calculated value.