awk - Adding a column with value found in next line, if patter is matched

I am trying to transform this file

keyn,assert,code
"11","1","25"
"11","1","21"
"11","1","40"
"12","0","35"
"12","0","10"

to this one:

keyn,assert,code,code
"11","1","25","21"
"11","1","40","0"
"12","0","35","0"
"12","0","10","0"

i.e. for the first instance of keyn, if assert == "1", print $3 of the next register at the end of the line and delete that line, and if assert == "0", print just "0" at the end of the line.

Until now, I tried this, without success:

awk  'BEGIN{OFS=FS=","} {num[NR] = $3; if ($2=="1") {print $0, num[i+1]} else {print $0,"0" }}' file

I'd use a couple of variables to carry values over to the next record:

awk '
    BEGIN {FS = OFS = ","; zero = "\"0\""}
    NR == 1 {print $0, "code"; next}
    prev != "" {
        print prev, $1 == key ? $3 : zero
        prev = ""
        if ($1 == key) next
    }
    {key = $1}
    $2 ~ /1/ {prev = $0; next}
    {print $0, zero}
' file

This works on the sample data you show. No guarantees.

I think this is what you're trying to do:

$ cat tst.awk
BEGIN { FS=OFS="," }
NR == 1 {
    print $0, "code"
    next
}
$1 != prev {
    prev = $1
    if ( $2 == "\"" 1 "\"" ) {
        saved = $0
        next
    }
}
{
    print ( saved == "" ? $0 OFS "\"0\"" : saved OFS $3 )
    saved = ""
}
END {
    if ( saved != "" ) {
        print saved OFS "\"0\""
    }
}

<p>

$ awk -f tst.awk file
keyn,assert,code,code
"11","1","25","21"
"11","1","40","0"
"12","0","35","0"
"12","0","10","0"

I'm assuming above that if your last row of input starts with a new keyn value you want that line printed with a "0" at the end, e.g.:

$ cat file
keyn,assert,code
"11","1","25"
"11","1","21"
"11","1","40"
"12","0","35"
"12","0","10"
"13","1","10"

<p>

$ awk -f tst.awk file
keyn,assert,code,code
"11","1","25","21"
"11","1","40","0"
"12","0","35","0"
"12","0","10","0"
"13","1","10","0"

but it's obviously an easy tweak to do just about anything else in that case if that's not what you need.