perl read and filter input from file

I have data input file having format as below example,

<name> <attr1> <attr2> <attr3> <working_area> <date>
alan x x x /path/to/alan_work/a Wed_May_17_04:17:40_2023
alan x x x /path/to/alan_work/b Sun_May_28_21:22:52_2023
alan x a x /path/to/alan_work/c Sun_May_28_22:25:47_2023
ben x x x /path/to/ben_work/a Wed_May_17_04:18:44_2023
ben a b x /path/to/ben_work/b Wed_May_17_08:19:47_2023
charles a a a /path/to/charles_work/a Wed_May_17_04:17:40_2023
charles a a a /path/to/charles_work/b Thurs_May_18_04:17:40_2023
ben x x x /path/to/ben_work/c Fri_May_19_04:18:44_2023

I am writing perl script and want to achieve below criteria:

1. For same user, if all attributes 1, 2 and 3 are the same among 2 or more different working area, get the working area path that with latest date attribute

Expected Output:

/path/to/alan_work/b
/path/to/alan_work/c
/path/to/ben_work/c
/path/to/ben_work/b
/path/to/charles_work/b

Short snippet (I have no idea how to proceed)

open(FF, '<', $temp_file) or die "cannot open $temp_file";
    while (my $line = <FF>) {
      chomp $line;
      my @split_type = split(' ', $line);
	#no idea here
    } 

Since the values are separated with spaces, and the date components are separated with underscores, processing this is fairly straight forward.

We'll use the username and attributes as key to a hash, and replace the value of the hash with the workpath for the highest date value.

To make this work, we have to transform the date to a standard form that can be compared:

use strict;
use warnings;
use v5.10;

my $file = 'input.txt';
open my $fh, '<', $file or die "Could not open $file: $!\n";

my %paths;
while(<$fh>){
    /^</ and next;     # skip the header
    my ($name, $attr1, $attr2, $attr3, $workpath, $date) = split;
    my $key = "$name|$attr1$attr2$attr3";
    $date = transformDate($date);

    $paths{$key} = [$date, $workpath]
        if !defined $paths{$key} || $date gt $paths{$key}[0];
}

say $paths{$_}[1] for sort keys %paths;

# change date from: Wed_May_17_04:17:40_2023
#          to this: 2023051704:17:40
sub transformDate {
    my $date = shift;
    state $monthindex = {
        Jan => 1,  Feb => 2,  Mar => 3,
        Apr => 4,  May => 5,  Jun => 6,
        Jul => 7,  Aug => 8,  Sep => 9,
        Oct => 10, Nov => 11, Dec => 12,
    };
    my (undef, $month, $day, $time, $year) = split/_/, $date;
    sprintf('%d%02d%02d%s', $year, $monthindex->{$month}, $day, $time);
}

Edit: removed the alternative date parsing, since it was not needed after clarifying the date format.

Store the data in a hash keyed by the name, attributes, and the area, use dates as the values. Sort the areas by the values (you need to implement date comparison for your format, or parse it when populating the hash and populate the hash with comparable values) and return the last one.

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

# This needs to properly parse the dates, but for the example it
# works, as the dates to compare are always in the same month and never
# on the same day.
sub by_date {
    my ($dates_by_area, $A, $B) = @_;
    $dates_by_area->{$A} =~ /May_?([0-9]+)/;
    my $day_a = $1;
    $dates_by_area->{$B} =~ /May_?([0-9]+)/;
    my $day_b = $1;
    $day_a <=> $day_b
}

my $temp_file = shift;

open my $in, '<', $temp_file or die "cannot open $temp_file";
my %dates;
while (my $line = <$in>) {
    next if $line =~ /^</;

    my ($name, $attr1, $attr2, $attr3, $area, $date) = split ' ', $line;
    $dates{$name}{$attr1}{$attr2}{$attr3}{$area} = $date;
}

for my $name (keys %dates) {
    for my $attr1 (keys %{ $dates{$name} }) {
        for my $attr2 (keys %{ $dates{$name}{$attr1} }) {
            for my $attr3 (keys %{ $dates{$name}{$attr1}{$attr2} }) {
                my %dates_by_area = %{ $dates{$name}{$attr1}{$attr2}{$attr3} };
                my @sorted = sort { by_date(\%dates_by_area, $a, $b) }
                             keys %dates_by_area;
                say $sorted[-1];
            }
        }
    }
}

The structure collected in %data can be inspected using

use Data::Dumper;
warn Dumper \%data;

witch gives the following output for the sample:

$VAR1 = {
          'alan' => {
                      'x' => {
                               'x' => {
                                        'x' => {
                                                 '/path/to/alan_work/a' => 'Wed_May17_04:17:40_2023',
                                                 '/path/to/alan_work/b' => 'Sun_May_28_21:22:52_2023'
                                               }
                                      },
                               'a' => {
                                        'x' => {
                                                 '/path/to/alan_work/c' => 'Sun_May_28_22:25:47_2023'
                                               }
                                      }
                             }
                    },
          'ben' => {
                     'x' => {
                              'x' => {
                                       'x' => {
                                                '/path/to/ben_work/a' => 'Wed_May17_04:18:44_2023',
                                                '/path/to/ben_work/c' => 'Fri_May19_04:18:44_2023'
                                              }
                                     }
                            },
                     'a' => {
                              'b' => {
                                       'x' => {
                                                '/path/to/ben_work/b' => 'Wed_May17_08:19:47_2023'
                                              }
                                     }
                            }
                   },
          'charles' => {
                         'a' => {
                                  'a' => {
                                           'a' => {
                                                    '/path/to/charles_work/a' => 'Wed_May17_04:17:40_2023',
                                                    '/path/to/charles_work/b' => 'Thurs_May18_04:17:40_2023'
                                                  }
                                         }
                                }
                       }
        };

You gave no instructions what should happen if there are two different days for the same name, attributes, and area. The current implementation just uses the last corresponding line from the input.

Also, you can notice I switched to lexical filehandles to avoid problems bareword filehandles bring.
When using split ' ', you don't need to chomp, as this special form of split removes the trailing whitespace including a newline.

perl -MTime::Piece -nE '
    # extract fields
    ($u,$a1,$a2,$a3,$p,$_) = split;
    $id = "$u $a1 $a2 $a3";

    # massage date format into standard form
    y/[A-Za-z0-9]//cd;
    s/.*([A-Z][a-z]{2})[^\d]*/$1/;
    eval {
        $t = Time::Piece->strptime($_,"%b%d%H%M%S%Y")->datetime;
    } or do {
        # add error handling
        # (this also catches any header)
        next;
    };

    # save path if "better"
    if ($t ge $ts{$id}) {
        $ts{$id} = $t;
        $ps{$id} = $p;
    }

    # print results
    END { say for sort values %ps }
' datafile