count number of lines between two pattern match in file and delete all lines between pattern match only if count is more than 4

I have a file which contains text like below

Input file:

------start---------
first line
second line
third line 
fourth line
------end-----------
xyx
pqr
------start---------
first line
second line
third line 
fourth line
fith line
sixth line
------end-----------

I want a output file such that if lines between patterns "start" and "end" is more than 4 all i want to delete all those lines between pattern else i dont wish to touch them if count is less than or equal to 4

I need the output file like below, inside which i want to delete all lines between two pattern match only if the total count of line is more than 4

expected output file:

------start---------
first line
second line
third line 
fourth line
------end-----------
xyx
pqr
------start---------
------end-----------

I have used this sed command

sed -i '/start/,/end/{//!d}' filename

to delete lines between pattern match but it will not cover the case to avoid deletion of all lines when total line count between pattern match is less than or equal to 4

Using any awk and without reading all of the input into memory at once:

awk '
    inBlock {
        if ( /^-+end-+$/ ) {
            if ( gsub(/\n/,"&",rec) <= 4 ) {
                printf "%s", rec
            }
            inBlock = rec = ""
        }
        else {
            rec = rec $0 ORS
        }
    }
    !inBlock {
        print
    }
    /^-+start-+$/ {
        inBlock = 1
    }
' file

<p>

------start---------
first line
second line
third line
fourth line
------end-----------
xyx
pqr
------start---------
------end-----------

awk \
    -v s1='------start---------' \
    -v s2='------end-----------' \
'
    # accumulate lines between markers
	between { data = data RS $0 }

    # found start marker
	$0==s1 {
        # reset state
		between = NR
		data = $0
	}

    # print anything outside markers
	!between;

    # found end marker
	$0==s2 {
        # print data if fewer than 6 lines total
        #     (including the two marker lines)
        # else just print the markers 
		print (NR < between+6) ? data : s1 RS s2

        # reset state
        between = 0
		data = ""
	}
' filename

You can use perl instead of sed in a similar manner:

perl -0pe 's/------start---------\n\K(?:(?:(?!------(?:end|start)---------).)+?\n){5,}(?=------end-----------)//g' myfile

Here perl -0pe is alternative to sed -z, but it supports PCRE regexes, including lookaheads and capturing resets \K.

Regex itself means:

• ------start---------\n - start tag with newline,
• \K disregards previously matched sequence, staying in the same cursor position. Alternative to this could be more widely familiar (?<=------start---------\n), but \K has better performance,
• (?:(?:(?!------(?:end|start)---------).)+?\n){5,} - at least 5 lines that don't contain start or end tag,
• (?=------end-----------) lookahead checks, that matched sequence is followed by end tag.

Demo of regex here.

Using GNU sed

$ sed -Ezi.bak 's/(-+start-+\n)(([^-\n]*\n){5,})(-+end-+\n)//g' input_file
------start---------
first line
second line
third line
fourth line
------end-----------
xyx
pqr
------start---------
------end-----------

Perl has the same range operators as sed and awk, so you can do this in stream processing mode:

perl -ne 'push @l,$_ if /-+start-+/ .. /-+end-+/; print if $#l<0; if (/-+end-+/) { if ($#l<6) { print @l } else { print @l[0,-1] } @l=() }' input_file

Unrolled that looks like this:

# accumulate lines into array @l within range
push @l,$_ if /-+start-+/ .. /-+end-+/; 

print if $#l<0;       # print if empty (outside range)

if (/-+end-+/) {      # upon end...
   if ($#l<6) {       # ...if 6 or fewer lines accumulated:
      print @l;       # print entire range
   } else {           # ...if more than 6 lines:
      print @l[0,-1]; # print first and last
   } 
   @l=();             # ...empty @l
}

1. NF < 6 here since it's 4 standard lines + ----end---- line.

2. __ is the ON / OFF printing indicator flag.

echo '
------start---------
first line
second line
third line
fourth line
------end-----------
xyx
pqr
------start---------
first line
second line
third line
fourth line
fith line
sixth line
------end-----------' | 

mawk 'BEGIN { _+=_^= ORS = RS = "---" (FS = RS)       
              _^= ! (___ = _ += _+_)            } 
            (__ = $NF ~ /^[-]+(start|end)[-]*$/) < _ || 
           (!__ ? _ : (NF < ___ || $!NF = $NF)^(_ = !_)^_)' 

------start---------
first line
second line
third line 
fourth line
------end-----------
xyx
pqr
------start---------
------end-----------