Is there a way to obtain the SQLSTT error description in RPGLE/DB2 SQL for more informative error messages?

I am running RPGLE/DB2 SQL and want to get the SQLSTT error description to send back to the user or developers to better describe what happened. Right now we have to google the SQLSTT description after receiving the error.
This seems like something I should be able to query from somewhere but I cannot find the solution.

    PSTMT='create or replace alias QTEMP.TheirIIM for '
          +%trim(xOtherSys)+'IIM';
    exec sql execute immediate :PSTMT;
    @SQLERR(SQLSTT:'ALIAS' :%trim(xOtherSys)+'IIM');         

   Dcl-proc @SQLERR;
   Dcl-pi   @SQLERR IND;
        SQLSTATE CHAR(5) const;
        Action   CHAR(20) const;
        File     CHAR(20) const;
   End-pi;                               

      Select;
        When ACTION = 'ALIAS';    // Create Alias failed
         ** If SQLSTT > '03000';**
            Subject = %Trim(DFTLIB) + ' ' +
             'INTCRTORD Pgm Error: Create Alias failed. ';
            Message = %Trim(ACTION) +
            ': CREATE ALIAS for '+ %Trim(File) +
            ' statement failed with SQLSTT:'+SQLSTT+
            '\n RUN ABORTED!';
            $Error = *ON;
          ENDIF;          

I'd like to actually retrieve what the SQLSTT means and send that back in my message.

You can also get the full error message with the sql function :

get diagnostics

The MESSAGE-TEXT contain the detailed error message :

 DCL-S  DataText VARCHAR(200);
 Exec SQL
      prepare c1 from :sqlw ;
    if (SQLCOD < 0);
      Exec SQL GET DIAGNOSTICS EXCEPTION 1
                 : DataText = MESSAGE_TEXT ;
      snd-msg DataText;
    ENDIF;

see the IBM documentation
GET DIAGNOSTICS

or detailed examples in Simon's blog

Edit: You need to use the SQLCODE instead of the SQLSTATE.
The SQLCODE ties directly to an IBM i error message description.

You may like this snippit from one of my RPGLE SQL programs:

  *********************************************************************
  * Determine the Success/Failure of an SQL operation by checking     *
  * SQLCODE and SQLSTATE.                                             *
  * ---                                                               *
  * Return *ON for success; *OFF for failure                          *
  * ---                                                               *
  * Send a message to the program message queue if a failure occurs.  *
  *********************************************************************

 P CheckSQL        B
 D CheckSQL        PI              N
 D  EOF_IS_OK                      N   Const Options(*NoPass)
 D  ParmWarnOnly                   N   Const Options(*NoPass)
 D  ParmLocation                 32    Const Varying
 D                                     Options(*NoPass)

 D WarningOnly     S               N   Inz(SQL_ABORT)
 D StmtLocation    S             32    Varying
 D                                     Inz('Unspecified location')
 D SQLerrID        S              7
 D SuccessFlag     S               N
 D IgnoreEOF       S               N   Inz(*On)

  /Free

   If %Parms > 0 ;
      IgnoreEOF = EOF_IS_OK ;
      If %Parms > 1 ;
         WarningOnly = ParmWarnOnly ;
         If %Parms > 2 ;
            StmtLocation = ParmLocation ;
         EndIF ;
      EndIF ;
   EndIF ;
   SQLErrID = *Blanks ;
   SuccessFlag = *On ;
   Select ;
      When SQLCOD = -842 and SQLSTT = '08002' ; // Already connected
         SuccessFlag = *On ;
         SQLerrID = 'SQL9999' ;
      When SQLCOD = 100 and IgnoreEOF ;
         SuccessFlag = *On ;
      When SQLSTT <> *Zero ;
         SuccessFlag = *Off ;
         SQLerrID = 'SQL9999' ;
      When SQLCOD <> *Zero ;
         SuccessFlag = *Off ;
         SQLerrID = 'SQL9999' ;
      When SQLCOD = *Zero ;
         SuccessFlag = *On ;
      Other ;
         SuccessFlag = *On ;
   EndSL ;
   If SQLCOD = *Zero or (SQLCOD = 100 and IgnoreEOF) ;
      // Couldn't think of another way to word it with readability
   Else ;
      EvalR SQLerrID = %EditC(%Abs(SQLCOD): 'X') ;
      If %Subst(SQLerrID: 3: 1) = '0' ;
         %Subst(SQLerrID: 1: 3) = 'SQL' ;
      Else ;
         %Subst(SQLerrID: 1: 2) = 'SQ' ;
      EndIF ;
      AcePgmMsg(SQLerrID: SQLERM: '*COMP') ;
   EndIF ;

   If Not SuccessFlag ;
      If WarningOnly ;
         AcePgmMsg('CPI8859'
              : 'Error occurred at ' + StmtLocation: '*COMP') ;
      Else ;
         SendEscape('CPF9898'
                  : 'Abort due to SQL error at ' + StmtLocation
                   ) ;
      EndIF ;
   EndIF ;
   Return SuccessFlag ;

  /End-free

 P CheckSQL        E

This works by utilizing the SQL error messages file QSQLMSGF. SQLERM is the error code you're looking for. I think you an figure out AcePgmMsg and create your own.... all it does, is SNDPGMMSG with the appropriate MSGID and MSGF specified, with MSGTYPE set to the specified value. So if it's not clear, let's say you have an SQLERM value of 1234. Look at the message description for SQL1234 of message file QSQLMSGF and you will find what that error code means. FOr values above 9999, the message code is SQ + code (SQ23456). So, at a minimum, you can stop doing google searches; the answer is local to your system.

Let me know if you need more.

Have fun.

To control the error, we usually use SQLCODE (this has already been written about here) - the value 0 corresponds to successful execution, negative values - an error.
The specific error type and its detailed description can be obtained via get diagnostics condition. For example like this:

  begsr isSQLError;
    If SQLCOD < 0;
      exec sql get diagnostics condition 1 :ErrState = RETURNED_SQLSTATE, :errText = MESSAGE_TEXT;
      LogText(MpJobName + errText);
      LogMsg(errCode: ErrState);

      return *off;
    EndIf;
  endsr;

Well, or, if you like, you can arrange it as a separate procedure.