How can I loop through 2 Range-Objects in the same Loop in VBA for Excel?

I tried to comment in the Code below what I try to do. I know how to keep the selected Cells for the old value which got changed. It works with only one cell, but not more. I don't get it how I can loop through the 2 Range-Objects in the same For-Loop. I don't think it will work with a For-Each.

Dim OldValue As Range

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
  Dim FirstFreeRow As Long
  Dim tCell As Variant
  Dim I As Integer
  
  If Sh.Name = "Changes" Then Exit Sub
  If Sh.Name = "Tabelle2" Then Exit Sub
  If Intersect(Target, Sh.Range("A2:Z550")) Is Nothing Then Exit Sub
  
  Application.EnableEvents = False
  
  For I = 0 To Target.Count 'Go through all changed Cells
  
  tCell = Target.Cells(I, 1)

  With Sheets("Changes")
    FirstFreeRow = .Cells(Rows.Count, 1).End(xlUp).Row + 1
    With .Rows(ErsteFreieZeile) '.EntireRow
       .Cells(1) = tCell.EntireColumn.Cells(1)
       .Cells(2) = tCell.EntireRow.Cells(2)
       .Cells(3) = tCell.EntireRow.Cells(3)
       .Cells(4) = OldValue(I, 1).Value 'Put the old value in here
       .Cells(5) = tCell.Range("A1").Value
       .Cells(6) = Environ("username")
    End With
  End With

  Next I
  
  Application.EnableEvents = True
End Sub

Public Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)

Set OldValue = Target 'Save all selected Cells

End Sub

Sidequestion: If you use Cut and Paste then you don't have the old Value obviously, because you have a new selcted cell. Is there a way too? If not, doesn't matter.

Thanks.

Edit:
I am not allowed yet to post images directly. So it is posted as a link instead. Apologies. The Images shows how the Changes are supposed to be documented.

Does this make it more clear? I only have "Tabelle 1". "Tabelle 2" is something else, doesn't matter here.

You have several possibilities to loop over all cells of a Range:

A) Loop using Count (of cells)

Dim i As Long
For i = 1 To target.Count
    Debug.Print "Method A ", target(i).Address
Next

As you can see, you use only a single index into the range when you use this method

B) Loop over rows and columns

Dim row As Long, col As Long
For row = 1 To target.Rows.Count
    For col = 1 To target.Columns.Count
        Debug.Print "Method B ", target(row, col).Address
    Next col
Next row

Now you use 2 indizes into the range, the row and the column. Note that those indizes represent relative numbers, so if your range is "E5:G10", target(1, 1) is the first row and first column of that range, that is cell E5.

C) Using a foreach loop.

Dim cell As Range
For Each cell In target
    Debug.Print "Method C ", cell.Address
Next cell

In most cases that is the easiest way.

I see at least 2 issues in your code:
The first is that you use the first method (using count) for the loop but reads the cell from the target range using 2 indizes. If you have 3 rows by 4 colums in your range (so count = 12), you would read 12 cells from the first row which is not what you want.

Second is that you miss the Set keyword (and you declare tCell as Variant instead of Range. Now id tCell = Target.Cells(I, 1), tCell will get the content of the Range. This will give you a runtime error later in your code (tCell.EntireColumn cannot work if tCell is a value).
In VBA, you need to use the keyword Set to assign a reference to an object to a variable: Set tCell = Target.Cells(I, 1)