In VBA how to check no value is passed to a function using Dates?

I wrote a function that returns the earlier of two dates as a date object.

Function ReturnEarlierDate(newDate, existingDate) As Date
    deltad = DateDiff("d", CDate(newDate), CDate(existingDate))
    If deltad > 0 Then
        ReturnEarlierDate = CDate(newDate)
    End If
        ReturnEarlierDate = CDate(existingDate)
End Function

I want the function to use the existingDate, if only one parameter is passed and vice versa, only newDate if no existingDate is provided.

Sub Test()
    Dim arrayValues(2)
    arrayValues(1) = #10/10/2023#
    Debug.Print ReturnEarlierDate(arrayValues(1), arrayValues(0))
End Sub

The return value I want it 10/10/2023 and not 00:00:00

Your function is not expecting 2 Dates as parameters, it is expecting 2 Variants. A Variant is a kind of placeholder saying "It can be everything". In your case you are passing a date as first and an empty value as second value. "Empty" means that a Variant was not initialized and simply doesn't hold anything. This can be checked with IsEmpty.

If IsEmpty(newDate) Then
    ReturnEarlierDate = CDate(existingDate)
ElseIf IsEmpty(existingDate) Then
    ReturnEarlierDate = CDate(newDate)
Else
    (...your code here)

While the check for empty is easy, you have a bigger issue with your function: It doesn't check if the two parameters are really dates. So if you would call it with one of the parameters being a String, you would get a type mismatch runtime error.

You could completely avoid that by dealing with datatype Date. The only drawback would be that it is no longer possible to check if one of the parameters is empty by using IsEmpty (emtpy is available only for Variants). Dates in VBA (and in Excel) are stored as numbers (of type Double). Numbers in VBA are initialized with value 0, so in your function, you have to check for 0. Note that there is no longer the need to use CDate inside the function.

Function ReturnEarlierDate(newDate As Date, existingDate As Date) As Date
    If newDate = 0 Then
        ReturnEarlierDate = existingDate
    ElseIf existingDate = 0 Then
        ReturnEarlierDate = newDate
    ElseIf newDate < existingDate Then
        ReturnEarlierDate = newDate
    Else
        ReturnEarlierDate = existingDate
    End If
End Function

Sub Test()
    Dim arrayValues(2) As Date
    arrayValues(1) = #10/10/2023#
    Debug.Print ReturnEarlierDate(arrayValues(1), arrayValues(0))
End Sub

Now the function returns 0 (= 00:00:00) only if both dates where empty.

Slightly amend the function to check all possible scenarios:

1. Both dates supplied.
2. One of the two dates supplied.
3. No date supplied (amend to fit your needs).

If both dates have been supplied, the function returns a Long so the date return type is not appropriate; best to leave it as Variant.

Function EarlierDate(ByVal d1 As Date, ByVal d2 As Date) As Variant
    Select Case True
        Case d1 > 0 And d2 > 0:
            EarlierDate = DateDiff("d", d1, d2)
        Case d1 > 0:
            EarlierDate = d1
        Case d2 > 0:
            EarlierDate = d2
        Case Else:
            Err.Raise 1001, , "No date supplied."
    End Select
End Function

To test it:

Sub T()

    Dim arrayValues(2)
    arrayValues(1) = #10/10/2023#
    Debug.Print EarlierDate(arrayValues(1), arrayValues(0))
    
    '10/10/2023 
End Sub

As dates are basically stored as numeric vales you can check if they are greater than 0.

Date Data Type (Visual Basic)

Function ReturnEarlierDate(ByVal newDate As Date, ByVal existingDate As Date) As Date
    If newDate = 0 Then
        ReturnEarlierDate = existingDate
        Exit Function
    ElseIf existingDate = 0 Then
        ReturnEarlierDate = newDate
        Exit Function
    End If
    
    deltad = DateDiff("d", newDate, existingDate)
    If deltad > 0 Then
        ReturnEarlierDate = newDate
    Else
        ReturnEarlierDate = existingDate
    End If
End Function

Sub Test()
    Dim arrayValues(2) As Date
    arrayValues(1) = CDate(#10/10/2023#)
    Debug.Print ReturnEarlierDate(arrayValues(1), arrayValues(0))
End Sub

> I want the function to use the existingDate, if only one parameter is
> passed [...]

If you want the function to work with only one parameter passed, you can use Optional parameters.

Function ReturnEarlierDate1(Optional ByVal newDate As Date, Optional ByVal existingDate As Date) As Date
    If IsMissing(newDate) Then
        ReturnEarlierDate1 = existingDate
        Exit Function
    ElseIf IsMissing(existingDate) = 0 Then
        ReturnEarlierDate1 = newDate
        Exit Function
    End If
    
    deltad = DateDiff("d", newDate, existingDate)
    If deltad > 0 Then
        ReturnEarlierDate1 = newDate
    Else
        ReturnEarlierDate1 = existingDate
    End If
End Function


Sub Test1()
    Dim arrayValues(2) As Date
    arrayValues(1) = CDate(#10/10/2023#)
    Debug.Print ReturnEarlierDate1(, arrayValues(1))
End Sub