Setting a dynamic variable

I'm trying to use, lets say, a didynamic namic variable.

Example:

set i 1
set data_select$i [$txtvar get all]

I'm getting a 'doesn't exist' variable error.

The second half of the equation "[$txtvar get all]" is working fine.

is there any way to set a variable with another variable value?

There are two standard ways to do what you asked, and one standard replacement that doesn't do what you asked but does do what many people need when they try to do this.

Variable Named Variables: upvar

Make an alias to the variable with upvar, and then use the simple name. This is particularly common when the variable name is passed as an argument to a procedure.

proc foo {varName} {
    upvar $varName var
    puts "$varName is $var"
}

foo data_select$i

However, you can make an alias to a variable in the current stack frame by telling upvar to look there with the optional level argument:

upvar 0 data_select$i var
puts "data_select$i is $var"

The downside of this is you can't undo the making of such aliases.

Variable Named Variables: set

You can read a variable with the one-argument form of set, whose result is the content of the variable:

puts "data_select$i is [set data_select$i]" 

This is superior to using subst or eval; those have to re-parse things and require you to be very careful, but set guarantees that it will use its first argument as the name of a variable.

Variable Named Variables: arrays

Most of the time when people ask this question, they're better off using an associative array. It's much more efficient in this situation.

set i 1
set data_select($i) [$txtvar get all]
puts "the value was $data_select($i)"

This is because you can use substitutions in the name of an array element without disturbing how $ is used to indicate a read.

It can be done, but it's annoying

$ tclsh
% set i 1
1
% set data_select$i "hello"
hello
% set data_select1              # the variable exists
hello
% set data_select$i             # and you can use the var to fetch it
hello
% puts $data_select1            # you can dereference it directly, but ...
hello
% puts $data_select$i
can't read "data_select": no such variable
% puts ${data_select$i}
can't read "data_select$i": no such variable
% puts [set data_select$i]
hello

Tcl has no way to know that it's supposed to substitute $i first. Substitutions occur from left to right.

With a dictionary

% set data_select {}
% dict set data_select $i hello
1 hello
% puts [dict get $data_select $i]       # note the `$` for data_select
hello

I second the advise to use an array or dict. But if you absolutely need to access a variable whose name must be built from other pieces, you can create an alias using the upvar command:

% set i 1
1
% set data_select$i "hello"
hello
% upvar 0 data_select$i var
% puts $var
hello
% set var bye
bye
% puts $data_select1
bye