Get the average rank in excel

I have a list of columns based on date

property | 2023-04-10 | 2023-04-11 | 2023-04-12
A        |    0:10    |    0:20    |   0:30
B        |    0:05    |    0:12    |   0:35
C        |    0:02    |    0:10    |   0:40

I want to compute a column which has average rank, that is

property | average_rank
A        |     (1+1+3)/3
B        |     (2+2+2)/3
C        |     (3+3+1)/3

how do I achieve this in excel, also some of the cells have blank entries, in that case I would not like consider that cell while calculating the average rank

there are 100s of columns so I cannot enter them one by one in the average function

Combination of latest functions of Microsoft-365 may work.

=BYROW(
MAP(B2:D4,LAMBDA(x,RANK(x,INDEX(B2:D4,,COLUMN(x)-COLUMN(A2))))),
LAMBDA(rw,AVERAGE(rw))
)

We can avoid using of RANK() function using the following formula.

=BYROW(
MAP(B2:D4,LAMBDA(x,XMATCH(x,SORT(CHOOSECOLS(B2:D4,COLUMN(x)-MIN(COLUMN(B2:D4))+1),,-1)))),
LAMBDA(rw,AVERAGE(rw))
)

You can try the following, assuming no Excel version constraints as per the tag listed in the question:

=LET(in,B2:D4,BYROW(MAKEARRAY(ROWS(in),COLUMNS(in), LAMBDA(i,j,
 RANK(INDEX(in,i,j),INDEX(B2:D4,,j)))),LAMBDA(z, AVERAGE(z))))

Note

Under Excel for Web, I tested you can use INDEX(in,,j) instead of INDEX(B2:D4,,j). As @JosWoolley pointed out in the comment section, testing the formula using the name ìn produces a #CALC! (Nested array error) for desktop under O365. I tested also for this desktop version: Microsoft 365 Apps for Enterprise Version 2304 (Build 16327.20214 Current Channel). A possible bug or inconsistency in Microsoft update/release channel policy. I posted this issue in the Microsoft Feedback community, here is the link, in case you would like to vote for it.

Another workaround to avoid this error and keep using the name in, is to create a LAMBDA(B2:D4) function, i.e. "thunking the range" and name it in, then to refer it. It ensures the formula is easier to maintain (if you need to update the range, update it in one place only). For example:

=LET(in, LAMBDA(B2:D4), BYROW(MAKEARRAY(ROWS(in()),COLUMNS(in()), LAMBDA(i,j,
 RANK(INDEX(in(), i,j), INDEX(in(),,j)))),LAMBDA(z, AVERAGE(z))))

Notice how we call it: in().

Here is the output:

MAKEARRAY iterates over all elements of the input (in) and calculate the RANK for a given element (i,j) with respect to column j of in. Then we invoke BYROW on the MAKEARRAY result to calculate on each row the average.