How can I create the population size of different agents using csv input?

I have a csv with 7 columns that has data that represents the population sizes of different agents in my model. Each row will represent a different day in the model but that's not important right now.

ones twos threes fours fives sixes sevens
1 1 1 1 1 1 1 1
0 0 1 0 1 1 1 2
2 4 5 6 1 1 1 1
4 5 6 7 1 1 2 3

I'm not sure how to assign the values to the agents to create the populations. If you look at the first row I should have 1 of each turtle breed.

 extensions [csv]
    globals [ data ]
    
    breed[ones one]
    breed[twos two]
    breed[threes three]
    breed[fours four]
    breed[fives five]
    breed[sixes six]
    breed[sevens seven]
    
    to setup
      ca
      set data csv:from-file "data.csv"
      print data
      reset-ticks

      ; this is where I imagine I should assign the population sizes by the csv info. 
      create-ones ???
      create-twos
      create-threes
      create-fours
      create-fives
      create-sixes
      create-sevens


    end

Once you read a csv file with the csv:from-file primitive, you get a standard NetLogo list, which itself includes a sublist for each row. So, you would need to use standard NetLogo list primitives such as item and a foreach loop to parse your data and create your turtles.

Your csv file has too many columns, so I will provide an example with a smaller dataset. Let's assume we have a file called data.csv which looks like this:

ones,twos,threes
1,2,3
1,4,9

First, let's try to print the output of the csv:from-file to get a sense of how NetLogo represents your data:

observer > show csv:from-file "data.csv"
observer : [["ones" "twos" "threes"] [1 2 3] [1 4 9]]

This shows that the rows and the columns in the csv file are represented as a single list that includes three items, each of them a list of three items themselves. Therefore, all you need to do is to treat your data as a standard nested NetLogo list and use the list-related primitives to manipulate your data and retrieve necessary information.

Here is how I would write the code you intended to write:

extensions[csv]

globals [ data ]

breed [ones one]
breed [twos two]
breed [threes three]

to setup
  clear-all
  
  set data but-first csv:from-file "data.csv"
 
  let first-row item 0 data
  
  let num-ones item 0 first-row
  let num-twos item 1 first-row
  let num-threes item 2 first-row
  
  create-ones num-ones [ set shape "triangle" fd 10 ]
  create-twos num-twos [ set shape "square"  fd 10 ]
  create-threes num-threes [ set shape "circle" fd 10 ]
  
  reset-ticks
end

• Notice that I used the but-first primitive to get rid of the first item in the dataset that includes column headers because we know the order of variables in the dataset, so we do not need that first row.
• If you have a large dataset, you can also use the foreach primitive to iterate over the rows and columns instead of defining a separate variable for each cell.

Note: You can refer to the NetLogo Dictionary for more information about all the list-related primitives: https://ccl.northwestern.edu/netlogo/docs/dictionary.html#listsgroup