Quick Excel Formula - Reorder Array

I require a reorder formula without adding any extra cells on the sheet (≠helpers).

I'd like to reorder the 10 vertical cells located in AV63-72 currently in numerical order (2.94-3.35) = SOURCE, in the 10-cells selected array just below (=RESULTs displayed as it should be), according to the positions & values in the 10-cell array just left of the selected=INSTRUCTIONS column.

The vertical positions in all three arrays correspond vertically as static 1-10, but the values for the positions in the INSTRUCTION change as the sheet expands.

So, the instructions for the "2.94" in AV63 being in the 1st position (1.10) would be to write in turn in the 5th position in the RESULT array, where the formulas would be.

Can this be done just leveraging on the data shown, without adding any extra helper arrays on the sheet?

Try this:

=INDEX($AV$63:$AV$72,MATCH(ROW(AV73)-ROW($AV$73)+1,$AU$73:$AU$82,0))

FORMULA EVOLUTION

1) Mission statement

REORDER THE LIST

2) Breaking up the mission statement

=INDEX(THE DATA LIST, THE INDEX FOR THE GIVEN ROW)

3) Specifying THE DATA LIST

=INDEX($AV$63:$AV$72, THE INDEX FOR THE GIVEN ROW)

4) Breaking up THE INDEX FOR THE GIVEN ROW

=INDEX($AV$63:$AV$72,MATCH(THE RELATIVE ROW NUMBER, THE INSTRUCTION LIST, PRECISE RESULT))

5) Specifying PRECISE RESULT

=INDEX($AV$63:$AV$72,MATCH(THE RELATIVE ROW NUMBER, THE INSTRUCTION LIST,0))

6) Specifying THE INSTRUCTION LIST

=INDEX($AV$63:$AV$72,MATCH(THE RELATIVE ROW NUMBER,$AU$73:$AU$82,0))

7) Breaking up THE RELATIVE ROW NUMBER

=INDEX($AV$63:$AV$72,MATCH( THIS ROW NUMBER - THE FIRST ROW OF THE RESULT LIST + 1 ,$AU$73:$AU$82,0))

8) Specifying THE FIRST ROW OF THE RESULT LIST

=INDEX($AV$63:$AV$72,MATCH( THIS ROW NUMBER - ROW($AV$73)+1,$AU$73:$AU$82,0))

9) Specifying THIS ROW NUMBER

=INDEX($AV$63:$AV$72,MATCH(ROW(AV73)-ROW($AV$73)+1,$AU$73:$AU$82,0))

FORMULA EXPLODED

=INDEX(                          Pick from
      $AV$63:$AV$72,             the data list
      MATCH(                     the element with index equal to the row whose value is equal
            ROW(                 to the row
                AV73             of this row
               )
            -                    minus
            ROW(                 the row
                $AV$73           of the initial row of the result list
               )
            +1,                  plus one
            $AU$73:$AU$82,       among the instruction list
            0                    with precision
           )
      )

FORMULA NOTED

=INDEX($AV$63:$AV$72,MATCH(ROW(AV73)-ROW($AV$73)+1,$AU$73:$AU$82,0))
|  A  |      B      |  C  |    D    |    E     | F|      G      |H|

We need to search the list of instruction (part G) for each number from 1 to 10. We use a match function (part C) to search the list of instruction (part G) with precision (part H). Our results will be listed in a column, therefore each result will be stored in a row of said column. Since we need the series of number from 1 to 10, we take the row number for the given cell (part D) minus the row number for the starting cell of the results list (part E) plus 1 (part F). Note the relative reference of the given cell (part D) and the absolute reference of the starting cell of the results list (part E); said references will allow us to drag the cell down to easily change the relative references while keeping the absolute one. This will return us a 1 for the first cell of the result list, a 2 for the second cell of the result list, a 3 for the third cell... and so on. Thanks to this, our match function (part C) will find at what row of the instruction list is stored the number equal to the given row of the result list. We can use this result to search the data list (part B) using a index function (part A).

The whole list of results will ultimately have these formulas: