Autolisp function that Increment numbers intext or mtext +1

I'm not overly familar with AutoLISP having a problem writing a script that increments numbers in Text or MText by 1, preferably all selected text.

(defun c:IncrementTextNumbers (/ ss obj)
  (setq ss (ssget '((0 . "TEXT")(62 . 1))))
  (if ss
    (progn
      (setq obj (ssname ss 0))
      (while obj
        (if (and (= (cdr (assoc 0 (entget obj))) "TEXT")
                 (numberp (atoi (cdr (assoc 1 (entget obj))))))
          (progn
            (setq num (atoi (cdr (assoc 1 (entget obj)))))
            (setq new-num (+ num 1))
            (command "_.CHANGE" obj "" new-num)
          )
        )
        (setq obj (ssname ss (1+ (ssname ss (sslength ss) obj))))
      )
      (princ "\nHighlighted text numbers incremented successfully.")
    )
    (princ "\nNo highlighted text objects found.")
  )
  (princ)

Selection Set Processing

The main issue with your code is the method used to iterate over the selection set - specifically, this line:

(setq obj (ssname ss (1+ (ssname ss (sslength ss) obj))))

The ssname function accepts as arguments a selection set and an index; here, in the innermost expression, you are supplying a selection set (ss), an index ((sslength ss)), and an entity name (obj). Also ssname returns an entity name, which you cannot increment with the 1+ function.

I would suggest studying my tutorial on Selection Set Processing to understand various ways of iterating over a selection set.

For this particular example, I might use the 'reverse repeat' technique described in my tutorial, as this yields concise & efficient code e.g.:

(defun c:IncrementTextNumbers ( / idx sel )
    (if (setq sel (ssget "_:L" '((0 . "TEXT,MTEXT"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                ;; ... do stuff ...
            )
        )
    )
    (princ)
)

Here, you'll also note that I've revised the ssget expression in the following way:

• The "_:L" mode string excludes objects on locked layers - the underscore ensures that the non-localised version of the mode string is used.
• The use of TEXT,MTEXT in the selection filter allows the user to select both single-line text and MText, whilst excluding RTEXT.

String to Number Conversion

Firstly, I should note that this line in your program is not necessary:

(= (cdr (assoc 0 (entget obj))) "TEXT")

As you're already filtering for TEXT entities in the ssget selection filter.

Secondly, you should be aware that atoi will unhelpfully always return a numerical value, regardless of the input text, observe:

_$ (atoi "abc")
0

Hence, the expression (numberp (atoi ...)) will always return T, for all text content.

Since you also can't test for non-zero content in this case (as the content could be legitimately zero), I would suggest either using the distof function for the string to number conversion (as this function will return nil for non-numerical input), or if you want to restrict the input to only integers, you can use the wcmatch function to test whether the string contains only digits (or better yet, incorporate this test into the ssget selection filter).

Here's an example of each method:

Using distof

(defun c:IncrementTextNumbers ( / enx idx sel str )
    (if (setq sel (ssget "_:L" '((0 . "TEXT,MTEXT"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  str (cdr (assoc 1 enx))
            )
            (if (distof str 2)
                ;; ... do stuff ...
            )
        )
    )
    (princ)
)

Using wcmatch (testing for positive integers)

(defun c:IncrementTextNumbers ( / enx idx sel str )
    (if (setq sel (ssget "_:L" '((0 . "TEXT,MTEXT"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  str (cdr (assoc 1 enx))
            )
            (if (wcmatch str "~*[~0-9]*")
                ;; ... do stuff ...
            )
        )
    )
    (princ)
)

Using the ssget filter (testing for positive integers

(defun c:IncrementTextNumbers ( / enx idx sel str )
    (if (setq sel (ssget "_:L" '((0 . "TEXT,MTEXT") (1 . "~*[~0-9]*"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  str (cdr (assoc 1 enx))
            )
            ;; ... do stuff ...
        )
    )
    (princ)
)

Using entmod in place of Commands

Finally, you could make use of entmod to modify the content of the drawing database directly, rather than performing this operation using an AutoCAD command (which is slower and less reliable, as you are reliant upon the order of the prompts remaining unchanged between AutoCAD releases).

Consider the following code:

(defun c:IncrementTextNumbers ( / enx idx itm sel )
    (if (setq sel (ssget "_:L" '((0 . "TEXT,MTEXT") (1 . "~*[~0-9]*"))))
        (repeat (setq idx (sslength sel))
            (setq idx (1- idx)
                  enx (entget (ssname sel idx))
                  itm (assoc 1 enx)
            )
            (entmod (subst (cons 1 (itoa (1+ (atoi (cdr itm))))) itm enx))
        )
    )
    (princ)
)

You should use (entmod ) instead of change. Also simplified Your sample. Try this code.

(defun c:IncrementTextNumbers (/ ss obj)
      (setq ss (ssget '((0 . "*TEXT"))))
      (if ss
        (progn
		  (setq index 0)
          (setq obj (ssname ss index))
          (while obj
			(setq content (cdr (assoc 1 (entget obj))))
			(setq num (atoi content))
            (if (numberp num)
              (progn
                (setq new-num (1+ num ))
				(setq ed (entget obj)) 
				(setq ed (subst (cons 1 (itoa new-num)) (assoc 1 ed) ed)) 
				(entmod ed) 
              )
            )
			(setq index(1+ index ))			
            (setq obj (ssname ss index))
          )
          (princ "\nHighlighted text numbers incremented successfully.")
        )
        (princ "\nNo highlighted text objects found.")
      )
      (princ)
)