Excel VBA Disabling Shortcut Keys Sometimes Disables Data Entry

Why is my Code disabling even data entry randomly and occasionally, but working most of the time even when I isolate it and remove all other macros?

The code disables pretty much all shortcut keys, but should not affect simple data entry.

Option Explicit
Rem mod__ShortCutKeys

' Ctrl = "^"
' Alt = "%"
' Shift = "+"
' Combinations ("^", "%", "+", "^%", "^+", "%+", "^%+")

Rem Declare Variables
Dim Ctrl As String
Dim Alt As String
Dim Shift As String
Dim CtrlAlt As String
Dim CtrlShift As String
Dim AltShift As String
Dim CtrlAltShift As String

Dim KeyArray As Variant
Dim Key As Variant
Dim i As Long

Rem Public Sub ShortCutKeysInitializeVariables
Public Sub ShortCutKeysInitializeVariables()

    Ctrl = "^"
    Alt = "%"
    Shift = "+"
    CtrlAlt = "^%"
    CtrlShift = "^+"
    AltShift = "%+"
    CtrlAltShift = "^%+"

    KeyArray = Array(Ctrl, Alt, Shift, CtrlAlt, CtrlShift, AltShift, CtrlAltShift)

End Sub

Rem Public Sub ShortCutKeysDisable
Sub ShortCutKeysDisable()

    Rem Calls
    Call ShortCutKeysInitializeVariables

    ' Combinations
    For Each Key In KeyArray
        For i = 1 To 255
            On Error Resume Next
            Application.OnKey Key & Chr(i), ""
        Next i
    Next Key

    ' Functions keys
    For i = 1 To 12
        On Error Resume Next
        Application.OnKey "{F" & i & "}", ""
    Next i

    ' Combinations & Functions keys
    For Each Key In KeyArray
        For i = 1 To 12
            On Error Resume Next
            Application.OnKey Key & "{F" & i & "}", ""
        Next i
    Next Key

End Sub

Inspired by: Disable key or key combination

Why would this code stop me from entering any data? Happens randomly and only sometimes.

What I mean by data entry is that if I have a cell selected and I try to type data in that cell (uppercase or lowercase), it doesn't do anything. That problem persists even if I double-click in the cell to enter edit mode.

Closing and opening the file solves the problem, but it returns occasionally.

I'm using: Excel 2021 Pro Plus LTSC

As stated in the comments, Application.Onkey should not have any impact on the behavior of key presses when you are in Edit mode, so this tells me that it's likely a bug with Excel/VBA.

It could possibly be due to the fact that you are setting a lot of OnKey targets and it causes some processes that handles key presses to behave erratically and even hang sometimes.

One thing to try would be to reduce the numbers of key combinations you set. You are trying to set 1,785 (7 x 255) OnKey targets in the first loop only!

If your goal is to target keyboard shortcuts, you can certainly reduce the range of characters from 32 to 255 since I really doubt that your keyboard can output non-printable ascii characters. You might even consider reducing it to 32 to 127 depending if you have accented characters on your keyboard.

If this isn't enought to fix it, you can try to reset the Application.OnKey combinations to their original state and re-do the disabling of all shortcuts to see if that resets things properly.

For instance, you could have a modified version of your procedure that makes use of the fact that passing Application.OnKey "...", Null will reset the behavior of the keys that were passed:

Sub ShortCutKeysToggle(Enabled As Boolean)

    Dim Proc As Variant
    If Enabled Then
        Proc = Null
    Else
        Proc = ""
    End If

    ShortCutKeysInitializeVariables

    ' Combinations
    For Each Key In KeyArray
        For i = 32 To 255
            On Error Resume Next
            Application.OnKey Key & Chr(i), Proc
        Next i
    Next Key

    ' Functions keys
    For i = 1 To 12
        On Error Resume Next
        Application.OnKey "{F" & i & "}", Proc
    Next i

    ' Combinations & Functions keys
    For Each Key In KeyArray
        For i = 1 To 12
            On Error Resume Next
            Application.OnKey Key & "{F" & i & "}", Proc
        Next i
    Next Key

End Sub

Then, you could have the following procedures to toggle or reset the keys when you get the bug that you have.

Sub ShortCutKeysEnable()
    ShortCutKeysToggle True
End Sub

Sub ShortCutKeysDisable()
    ShortCutKeysToggle False
End Sub

Sub ShortCutKeysReset()
    ShortCutKeysToggle True
    ShortCutKeysToggle False
End Sub

UPDATE: The following section is now irrelevant because it's not closing and reopening the file that solves the problem, but closing and reopening the Excel application.

And if that doesn't work, you mentioned that closing and opening the file solved the problem, so you could always just have a macro that closes the file and reopen it.

Sub CloseAndReopenActiveWorkbook()
    
    Application.ScreenUpdating = False
    
    Dim FileName As String
    FileName = ActiveWorkbook.FullName
    
    ActiveWorkbook.Close SaveChanges:=True
    Workbooks.Open FileName:=FileName
    
    Application.ScreenUpdating = True

End Sub

1. Make sure the code is placed in the appropriate module and is being
   executed correctly. Double-check that you are calling the
   ShortCutKeysDisable procedure from the appropriate location in your
   code or Excel workbook.
2. Check for any conflicting code or macros in your Excel workbook. If
   there are other macros or add-ins that manipulate shortcut keys,
   they might interfere with the behavior of the ShortCutKeysDisable
   procedure.
3. Review the code for any errors or inconsistencies. Make sure that
   the syntax is correct and all variables and objects are properly
   declared and used. Check for any typos or missing characters in the
   code.
4. Consider testing the code in a new, blank Excel workbook to isolate
   any potential conflicts with existing settings or configurations in
   your current workbook.
5. If the issue persists, try running the code on a different computer
   or Excel installation to see if the problem is specific to your
   environment.