Copying file with CMake to build folder - single solution for VS Code and Visual Studio

I have small project (minimum example) with 3 files:

foo.cpp
script.py
CMakeLists.txt

CMakeLists.txt:

cmake_minimum_required( VERSION 3.20 )
project( PythonCppExtension )


find_package( Python  COMPONENTS Interpreter Development )

add_executable(PyRun "foo.cpp")
target_include_directories(PyRun PUBLIC ${Python_INCLUDE_DIRS})

target_link_libraries(PyRun "${Python_LIBRARY_DIRS}/python3.lib") #I am using the Stable ABI 

add_custom_command(
        TARGET PyRun POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy
                ${CMAKE_SOURCE_DIR}/script.py
                ${CMAKE_CURRENT_BINARY_DIR}/script.py)

foo.cpp:

#define Py_LIMITED_API  0x03050000
#define PY_SSIZE_T_CLEAN

#ifdef _DEBUG
#undef _DEBUG
	#include <python.h>
#define _DEBUG
#else
	#include <python.h>
#endif

int main()
{
	const wchar_t* arg[] = { L"-i", L"script.py" };
	return Py_Main(n, const_cast<wchar_t**>(2));
}

The code may have issues and is just an example, but works for me.

I want to use cmake for building extensions that I can compile on Windows with Visual Studio or Visual Code and on Linux.

It works here, but the thing is that I still didn't figure out how to to make a single solution for both Visual Studio and Visual Code. The code above works for Visual Studio, that copy the script.py to the same folder of the executable PyRun. It does so because Visual Studio passes to CMAKE the full path of the folder output at the variable CMAKE_INSTALL_PREFIX:

 ... -DCMAKE_INSTALL_PREFIX:PATH="C:\Users\ ... \PythonCpp\out\install\x64-Debug" ...

When I compile with Visual Code I would have to update the cmake script to:

 add_custom_command(
            TARGET PyRun POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E copy
                    ${CMAKE_SOURCE_DIR}/script.py
                    ${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/script.py)

to copy the script file to the same folder of the executable, because the executable is copied to a Debug or Release folder within CMAKE_CURRENT_BINARY_DIR.

How do I handle such a issue to make one single cmake script?

This is an XY problem. You want to copy a file to the same directory as a target's output file. The way you do that is by using the $<TARGET_FILE_DIR:tgt> generator expression. Ex.

add_custom_command(
  TARGET PyRun POST_BUILD
  COMMAND "${CMAKE_COMMAND}" -E copy
    "${CMAKE_SOURCE_DIR}/script.py"
    "$<TARGET_FILE_DIR:PyRun>/script.py"
)

> The code above works for Visual Studio, that copy the script.py to the same folder of the executable PyRun. It does so because Visual Studio passes to CMAKE the full path of the folder output at the variable CMAKE_INSTALL_PREFIX:

I'm pretty sure CMAKE_INSTALL_PREFIX is not related to the problem here. Again, you were using ${CMAKE_CURRENT_BINARY_DIR} for the copy target location, which probably explains the behaviour you were getting. I suspect you might have been using a single-config generator for your VS Code project.

You can set the generator generally using the -G argument of the configure command, or in VS Code with the CMake Tools extension, using the cmake.generator setting (probably not a great idea to hardcode in workspace settings if you commit the workspace settings file to version control though (in that case, put the setting in your user setting.json file)).

Technically, you probably could work around a single-config generator problem in VS Code by using "cmake.buildDirectory": "${workspaceFolder}/build/${buildType}" (docs), but again, this would just be a workaround, and a bad one at that (if you put it in workspace settings and commit the workspace settings.json file, since it assumes single-config). On this point though, see also the issue ticket [Feature] Add option to specify cmake.buildDirectory for single- and multi-config generators, respectively #2426