How to convert values of recurring elements row by row to columns?

I receive an output of some script that gives rows containing element and it's value.
And there are only 3 elements that repeated with different values.
Want to convert them to columns with element name as column name and then values per column.

I have an output that gathers some server info and put it in file output.txt that looks like following:

real	0m0.537s
user	0m0.077s
sys	0m0.082s

real	0m0.512s
user	0m0.076s
sys	0m0.083s

real	0m0.498s
user	0m0.072s
sys	0m0.087s

So using google I handled it and with the following commands put all values into columns named real user and sys as following:

$ sed -i '/^$/d' output.txt
$ awk -F " " '{ print $2 }' output.txt > output2.txt
$ paste -d'\t' - - - < output2.txt | awk 'BEGIN { print "real\tuser\tsys"} {print $0}'

so the output looks like this one:

real	user	sys
0m0.537s	0m0.077s	0m0.082s
0m0.512s	0m0.076s	0m0.083s
0m0.498s	0m0.072s	0m0.087s

So I have 2 questions.

1. How to make column name to fit the column?
2. There should be a way to perform all this ugly stuff using one-liner. Does anyone have this one-liner?

You can easily do this with awk.

The script assumes there are always complete groups of 3 lines as in the example and that sys is the last.

awk 'BEGIN { print "real\tuser\tsys" }
$1=="real" { r=$2 }
$1=="user" { u=$2 }
$1=="sys" { s=$2; print r "\t" u "\t" s }' output.txt

or shorter

awk 'BEGIN { print "real\tuser\tsys" }
/^r/ { r=$2 }
/^u/ { u=$2 }
/^s/ { s=$2; print r "\t" u "\t" s }' output.txt

If you want a one-liner, remove line breaks and spaces.

awk 'BEGIN{print "real\tuser\tsys"}/^r/{r=$2}/^u/{u=$2}/^s/{s=$2;print r"\t"u"\t"s}' output.txt

Resulting output (tab-separated):

real    user    sys
0m0.537s        0m0.077s        0m0.082s
0m0.512s        0m0.076s        0m0.083s
0m0.498s        0m0.072s        0m0.087s

How to align the column headings with the data depends on what you need.

Since the string length of the data is 8 characters while the headings are 3 or 4 characters long, the TAB positions (with default TAB width 8) characters are different.

Based on this assumption, one way to fix this is to use two tabs when printing the headings:

BEGIN { print "real\t\tuser\t\tsys" }

Or you could use printf with field with.

awk 'function myprint(a, b, c) {
    printf("%-10s %-10s %-10s\n", a, b, c)
}
BEGIN { myprint("real", "user", "sys") }
/^r/ { r=$2 }
/^u/ { u=$2 }
/^s/ { s=$2; myprint(r, u, s) }' output.txt

prints

real       user       sys
0m0.537s   0m0.077s   0m0.082s
0m0.512s   0m0.076s   0m0.083s
0m0.498s   0m0.072s   0m0.087s

You can format any text into columns like this:

$ column -t file.txt
real      user      sys
0m0.537s  0m0.077s  0m0.082s
0m0.512s  0m0.076s  0m0.083s
0m0.498s  0m0.072s  0m0.087s

Depending what version of "column" you have (most Linux should be fine), you can probably solve the whole problem like this:

$ sed 's/^\S*//' output.txt | xargs -n3 echo | column -t -N real,user,sys
real      user      sys
0m0.537s  0m0.077s  0m0.082s
0m0.512s  0m0.076s  0m0.083s
0m0.498s  0m0.072s  0m0.087s

The "sed" removes the first column, the "xargs" groups the values into threes, and the "column" aligns everything and adds the headers.