Gradle: Multi-module project, project does not get transitive dependencies when using "implementation" instead of "compile"

this is build.gradle file of project A:

plugins {
    id 'java'
}

group = 'org.example'

repositories {
    mavenCentral()
}

dependencies {
    implementation project(':B')
    runtimeOnly project(':B')
}

and this is the build gradle file of project B:

plugins {
    id 'java'
}

group = 'org.example'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.slf4j:slf4j-simple:1.7.30'
    implementation 'org.slf4j:slf4j-api:1.7.30'
}

When I execute

> gradle :A:jar

I get compilation errors that the imports of slf4j cannot be found in project A but it is a transitive dependency of project B. If I change the build.gradle of project B to:

plugins {
    id 'java'
}

group = 'org.example'

repositories {
    mavenCentral()
}

dependencies {
    compile 'org.slf4j:slf4j-simple:1.7.30'
    compile 'org.slf4j:slf4j-api:1.7.30'
}

everythings works as expected in Gradle 6.9 but I want to upgrade to Gradle 7 and "compile" is deprecated. Does someone has a solution?

Yes, that is exactly the point of an implementation dependency.
It is needed for the implementation of the logic, but not for its API.
Thus it does not leak into the compile classpath of downstream projects and by that makes compilation faster and increases chance for cache-hits if build cache is used.

If you use slf4j classes in the API of B (parameters, return types, super classes, ...), then apply the java-library plugin (makes sense anyway if it is a library) and use the api configuration instead.

If you just want to use slf4j in A, then just also declare it as implementation dependency there.

Read https://docs.gradle.org/current/userguide/java_library_plugin.html#sec:java_library_separation for more information.