For xml-2-xml xslt it will output these text from no selected element

I want to transfer a xml to an another xml by xslt.

Below is my input xml:

<?xml version='1.0' encoding='UTF-8'?>
<message>
    <bo>
        <root>
            <payee>TMCH500000</payee>
        </root>
    </bo>
    <docTrans>
        <number>90001640</number>
        <docType>SETTLEMENT</docType>
        <createdOn>2023-04-12T10:21:31.231</createdOn>
    </docTrans>
</message>

Below is the xslt which I used to pick out some information.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="no"/>
  <xsl:template match="/message/bo/root">
    <node><xsl:value-of select="payee" /></node>
  </xsl:template>
</xsl:stylesheet>

With above xslt, seems there is only an element is selected.

But the output looks as below:

<node>TMCH500000</node>
    
    
        90001640
        SETTLEMENT
        2023-04-12T10:21:31.231
    

Expected output:

<?xml version='1.0' encoding='UTF-8'?>
<node>TMCH500000</node>

All these text of the element docTrans is selected as well.
I want to know why.

This is xslt playground which I used. I also test it in some other online xslt tool and get the same result.

There are built-in templates that kick in, in XSLT 3 you can prevent that by declaring <xsl:mode on-no-match="shallow-skip"/> e.g.

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="no"/>
  <xsl:mode on-no-match="shallow-skip"/>
  <xsl:template match="/message/bo/root">
    <node><xsl:value-of select="payee" /></node>
  </xsl:template>
</xsl:stylesheet>

Example fiddle.

A simple solution for XSLT 1.0 is to change your template so that it matches the document root (/) instead of matching /message/bo/root, e.g.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="no"/>
  <xsl:template match="/">
    <node><xsl:value-of select="/message/bo/root/payee" /></node>
  </xsl:template>
</xsl:stylesheet>

NB this assumes that there's exactly one /message/bo/root/payee; if there are more than one, the xsl:value-of will take the string value of just the first one, and if there are zero /message/bo/root/payee elements you'll end up with an empty <node/> root element.

To answer your question about why your stylesheet copies those text nodes, even though your code doesn't contain any explicit instructions to copy them, it's because as well as your explicit templates, there are templates which are built in (i.e. implicit, or default templates) including this one:

<xsl:template match="text()|@*">
  <xsl:value-of select="."/>
</xsl:template>

So another way to fix your original stylesheet would be add a template that would override that built-in template, e.g.

<xsl:template match="text()"/>