awk function to filter each column of a file in a loop based on value obtained from a second file

I am looking for an awk solution that enable to filter file2.txt for two conditions.

I have two files:
file1.txt

t1 9
t2 8
t3 5

file2.txt

t1 t2 t3
A/A:10,0:10 B/B:0,2:2 n/n
A/B:10,8:18 A/B:2,8:10 n/n
A/B:0,2:2 n/n B/B:0,1:1

desired output:

t1 t2 t3
A/A:10,0:10 n/n n/n
A/B:10,8:18 n/n n/n
n/n n/n n/n

Based on the values of file1.txt , for which I was able to create an array which store the value in B column

awk 'BEGIN { FS="\t"}
FILENAME=="file1.txt" { descr[$1]=$2 ; next }

I would like to filter the file2.txt, by iterating through the columns for the following conditions, in order to obtained what reported in the desired output. All samples in the header of file2.txt are included in file1.txt and the order is the same.

1. the third value (split by :) should be within a specific interval based on corresponding value from file1.txt
   For example the first value of sample t1 [10]:
   10>=(9/2) && 10<=(9*2) - is within the interval and thus keep the string as it is. The number 2 used in the division and multiplication is hard-coded and the number 9 is obtained from file1.txt. If not within the interval, then write n/n (for example first value for sample t2).

2. if the ratio of the first value/(sum of values in the second field) is included within an interval 0.1-0.25 or 0.75-0.9, then write n/n (split by , in this case).

For example second value of sample t2 [2,8] has a ratio 2/10=0.2, which is included in the interval, and thus need to set to n/n the field. The number 10 is derived from the sum of the two values in the field, separated by comma.

I tried a combination of for loop and if / split conditions, but I have some issues in order to iterate through the columns using the array, combined with the conditions.

Thank you in advance for any help!

Assuming:

• the values: 2, 0.1, 0.25, 0.75 and 0.9 are hard-coded.
• the intervals are closed, meaning the endpoints are included
  (if not, drop the = signs next to < and >).
• the column names in file1.txt may or may not be in the same order
  as the heder in file2.txt.

then would you please try the following:

awk -v OFS="\t" -v nn="n/n" '
    NR==FNR {a[$1] = $2; next}                                  # read file1.txt to associate the numerator value with the column name
    FNR==1 {
        for (i = 1; i <= NF; i++) b[i] = a[$i]                  # read the header line in file2.txt to associate the numerator value with the field number
        print                                                   # print the header line
        next
    }
    {                                                           # process bodies in file2.txt
        for (i = 1; i <= NF; i++) {                             # loop over the fields
            if ($i != nn) {
                split($i, c, /:/)
                split(c[2], d, /,/)
                if (! (c[3] >= b[i] / 2 && c[3] <= b[i] * 2))   # test the condition 1
                    $i = nn
                if (d[1] + d[2] > 0) {                          # avoid division-by-zero
                    ratio = d[1] / (d[1] + d[2])
                    if (ratio >= 0.1 && ratio <= 0.25 || ratio >= 0.75 && ratio <= 0.9)
                                                                # test the condition 2
                        $i = nn
                }
            }
        }
        print                                                   # print the line
    }
' file1.txt file2.txt

Output:

t1      t2      t3
A/A:10,0:10     n/n     n/n
A/B:10,8:18     n/n     n/n
n/n     n/n     n/n

BTW the 2nd column of the 2nd line B/B:0,10:10 in the desired output
should be a typo for n/n.