to get iteration count and total count over the rows from a column in table

We have a database table(source) with some million records in a table : Sample data like (extracted to a text file for sample)

 denied the payment
 the payment successfull and incident reported successfull
 Incident is been reported

while trying to get the distint words count on these 3 records . have replaced space with new line character and then sort uniq we have done .

sed 's/ /\n/g' file|sort|uniq -c >> new.txt 
output: 
denied   1
the      2
payment  2
successfull 2
Incident 2
is       1
been     1
reported 2

how can we also get number of rows for the above output: some thing like

values iterationcount    countofrows

denied       		1   	1
the          		2   	2
payment      		2   	2 
successfull  		2   	1  (Although this word is two times but available only in 1 row )
Incident     		2   	2
is           		1   	1
been         		1   	1
reported     		2   	2

You can't start by converting blanks to newlines and then try to add getting counts per the original lines.

Using any awk that supports delete array (which is most of them):

$ cat tst.awk
BEGIN { OFS="\t" }
{
    delete seen
    for ( i=1; i<=NF; i++ ) {
        wordCnt[$i]++
        if ( !seen[$i]++ ) {
            rowCnt[$i]++
        }
    }
}
END {
    print "values", "iterationcount", "countofrows"
    for ( word in wordCnt ) {
        print word, wordCnt[word], rowCnt[word]
    }
}

<p>

$ awk -f tst.awk file | column -s $'\t' -t
values       iterationcount  countofrows
payment      2               2
incident     1               1
the          2               2
and          1               1
been         1               1
reported     2               2
successfull  2               1
Incident     1               1
is           1               1
denied       1               1