VBA Toggle Button referencing in Visio

Sorry, probably an simple question but...

I'm trying to format a toggle button in VBA. I've 60+ buttons, each turning on/off layers and I'm trying to tidy this up. At the moment the formatting is done at the "Click" level, but that's a lot of duplication

Sub A2_Click() 
    Dim LyrNum As Integer ' Layer Number
    Dim RiserName As String
        LyrNum = A2.Data1 ' Pulled for Data1 field
        RiserName = "A2"
    If A2 Then            ' Button down
        Call ToggleRiser(LyrNum, 1, RiserName) ' Call Sub with Layer Number and "On"
      Else
        Call ToggleRiser(LyrNum, 0, RiserName) ' Call Sub with Layer Number and Off
   End If
End Sub

Which ideally then calls:

Sub ToggleRiser(ItmNbr As Integer, OnOff As String, Riser As Object)  ' Sub to switch layers on and off - ItmBr is the Layer Number; Riser is the Toggle Button Name

    Dim vsoLayer1 As Visio.Layer            ' Create Variable for Layer Info
    Set vsoLayer1 = Application.ActiveDocument.Pages.ItemU("Filler Boxes, Half Risers and Bass Box Layers").Layers.Item(ItmNbr) ' Set to specific Layer called
    
      
    If OnOff Then            ' Button down
        Riser.BackColor = RGB(230, 180, 50) ' Change Background Yell
    Else
        Riser.BackColor = RGB(129, 133, 219) ' Dark Blue
    End If
    
    vsoLayer1.CellsC(visLayerVisible).FormulaU = OnOff                                                 ' 
    vsoLayer1.CellsC(visLayerPrint).FormulaU = OnOff                                                   ' 

Turning on and off the layers works fine, but I'm missing something with the "Riser.BackColor" as VBA isn't recognising this as "A2.BackColor"

Not sure if this is because I need to evaluate "Riser" as something different than a string?

Thanks in advance!

Example file is here:
https://www.dropbox.com/s/io1nwnkmhs0a28c/ToggleScriptExample.vsdm?dl=0

Ideally I want to move the button formatting into the ToggleLayer Sub, or just find a better way in general - Counted again and there's 80+ buttons!

I don't have Visio on my home computer, so I can't check the example file or verify that any of this actually works.

As OP speculated, we need to pass the Riser as an Object instead of a string. Changing the call to Call ToggleRiser(LyrNum, 1, A2) should do the trick. However, we can extract all the data we need directly from the Riser to simplify the code:

Sub A2_Click() 
   Call ToggleRiser(A2)  ' Call Sub with Riser
End Sub

Sub ToggleRiser(ByRef Riser As Object)  ' Sub to switch layers on and off
    Dim vsoLayer As Visio.Layer            ' Create Variable for Layer Info
    Set vsoLayer = ActiveDocument.Pages("Filler Boxes, Half Risers and Bass Box Layers").Layers(Riser.Data1)
    
    'Toggle Layer
    vsoLayer.CellsC(visLayerVisible).FormulaU = Riser.Value                                                 
    vsoLayer.CellsC(visLayerPrint).FormulaU = Riser.Value

    'Color Riser
    If Riser.Value Then                     ' Button down
        Riser.BackColor = RGB(230, 180, 50)  
    Else
        Riser.BackColor = RGB(129, 133, 219)
    End If
End Sub

That said, we can do better by using a Wrapper Class to handle all of the Risers without wasting space on hard-coded Click events.

First, create a class, which I'll call RiserWrapper. This has a generic event-enabled ToggleButton that we can pass a Riser to which will catch all the click events.

Public WithEvents mRiser as MSForms.ToggleButton 'The passed Riser is event-enabled

Private Sub mRiser_Click()
'''The click event to toggle the desired layer and set the Riser color
    Dim vsoLayer as Visio.Layer
    Set vsoLayer = ActiveDocument.Pages("Filler Boxes, Half Risers and Bass Box Layers").Layers(mRiser.Data1)

    'Toggle the Layer
    vsoLayer.CellsC(visLayerVisible).FormulaU = mRiser.Value
    vsoLayer.CellsC(visLayerPrint).FormulaU = mRiser.Value

    'Color Riser
    If mRiser.Value Then
        mRiser.BackColor = RGB(230, 180, 50)  
    Else
        mRiser.BackColor = RGB(129, 133, 219)
    End If
End Sub

Next, we wrap the Risers and store them in a Collection. In ThisDocument:

Private Risers as Collection         'Collection to hold event-enabled Risers (must go at the top of the module)

Private Sub Document_RunModeEntered(ByVal doc As IVDocument)
'''Initialize drawing
    Dim ctl as OLEObject           'An Object on the drawing, access directly with .Object
    Set Risers = New Collection

    'Loop through the Control objects in the document to find the buttons
    For Each ctl in doc.OLEObjects
        'Filter by TypeName, enabling Click events for all CommandButtons
        If TypeName(ctl.Object) = "ToggleButton" Then Risers.Add NewRiser(ctl.Object)
    Next
End Sub

Private Function NewRiser(ByRef Riser as Object) as RiserWrapper
'''Wraps a given Riser and returns the wrapped object
    Set NewRiser = New RiserWrapper                     'Create wrapper instance
    Set NewRiser.mRiser = Riser                         'Wrap the Riser
End Function

And we're done!