Cleaning non-numericals from a column of cells

My ultimate goal is to make a macro that will clean up a row of telephone numbers, but it's been a while since I had to do any VBA programing, and I think I've forgotten something.

The first step should be to go to a cell and clean out any non-numerical data, for that I built the following code. It should work by selecting the first cell with data in the column, than it should just go to each cell, clean out the non-numerical data from the string and then move to the next cell in the column and repeat, until it comes across a blank row.

It's cycling through the rows, but it isn't cleaning the data.

Between the macro and the function this SHOULD work, I think. I'm not sure what I've done wrong, but I fear it's something very simple.

Sub Phonetest1()
ActiveCell.Range("A1").Select
Do

RemoveAllNonNums (A1)
ActiveCell.Offset(1, 0).Range("A1").Select
    
    
    Loop Until Application.CountA(ActiveCell.EntireRow) = 0
    
End Sub


Function RemoveAllNonNums(myCell As String)

   Dim myChar As String
   Dim x As Integer
   Dim i As String

   i = ""
   For x = 1 To Len(myCell)
     myChar = Mid(myCell, x, 1)
         If Asc(myChar) >= 48 And _
            Asc(myChar) <= 57 Then
            i = i & myChar
         End If
   Next
   RemoveAllNonNums = Val(i)

End Function

You need to assign the function's return value back to the cell:

Sub Phonetest1()
    Dim c As Range
    Set c = ActiveCell
    Do While Application.CountA(c.EntireRow) > 0
        c.Value = RemoveAllNonNums(CStr(c.Value))
        Set c = c.Offset(1) 'next row
    Loop
End Sub


Function RemoveAllNonNums(myCell As String)
    Dim myChar As String, x As Long, i As String
    i = ""
    For x = 1 To Len(myCell)
        myChar = Mid(myCell, x, 1)
        If Asc(myChar) >= 48 And Asc(myChar) <= 57 Then
            i = i & myChar
        End If
    Next
    RemoveAllNonNums = Val(i)
End Function