Distributing Values based on Cell value

I am trying to use the most efficient method to distribute values based on J13. In this example the value in J13 is three. I want the values in range J4:J12 to basically add "1" to each cell until the total sum = J13

I'm using this which gets the job done but i have other columns where I wanna do this same thing and it will take a long time to swap cell references.... any help would be appreciated!

> =iferror(IFS(j13=1,0,j13=2,1,j13=3,1,j13=4,1,j13=5,1,j13=6,1,j13=7,1,j13=8,1,j13=9,1,j13=10,1,j13=11,2,j13=12,2,j13=13,2,j13=14,2,j13=15,2))

Complementing Giselle explanation, you can use SEQUENCE inside WRAPCOLS to create "virtually" a range like this:

=WRAPCOLS(SEQUENCE(J13,1,1,0),ROWS(J3:J13)-1,0)

With SEQUENCE repeating 1 and WRAPCOLS making as many columns as necessary. WRAPCOLS will count the rows in between the starting cell and the end cell; so if you add one more row or delete one in between the formula will keep working.

Then, you just insert it into BYROW to sum those 1s row by row:

=BYROW(WRAPCOLS(SEQUENCE(J13,1,1,0),ROWS(J3:J13)-1,0),  LAMBDA(r,SUM(r)))

You can use the Sequence function in Google Sheet

Something like this:

=SEQUENCE(J13,1,1,0) 

The base formula is:

=SEQUENCE(rows, columns, start, step)

• The rows is the number of rows to return, so in this case the value in J13.
• And the columns is the number of columns to return, for this case since you only want to use column J, it will be 1.
• The start is the number to start the sequence at, for this case is 1.
• And lastly, step is the amount to increase/decrease each number in the sequence, since you want to add number ones only. The increase will be 0.

Here is an example:

Based on your comment to the previous answer that you would like the numbers in J4:J12 to 'wrap' if the number in J13 is big enough (which you should really have included in the original question as this was not obvious at all), you can try the following formula in J4:

=byrow(wrapcols(sequence(J13,1,1,0),rows(J4:J12),),lambda(row,sum(row)))

We are creating a column of 1s of length dictated by the number in J13, wrapping this array every 9 rows (based on the number of rows in the J4:J12 array) to make a 2D array, then summing across rows to achieve the desired behaviour.