Deploy .zip archive (python code) to Azure Function using TerraForm

I am having issues with uploading Python code to a Function App, in the sense that the function-app is created, but the code is not uploaded in the "Function" section, but rather in the "AppFiles" (there is no function in "Functions" in Azure Portal).

Here is my TerraForm code:

provider "azurerm" {
  features {}
}

data "archive_file" "function_zip" {
  type        = "zip"
  source_dir  = "../${path.module}/blob_storage_trigger"
  output_path = "../${path.module}/blob_storage_trigger.zip"
  depends_on = [null_resource.pip]
}

resource "null_resource" "pip" {
  triggers = {
    requirements_md5 = "${filemd5("../${path.module}/blob_storage_trigger/requirements.txt")}"
  }
  provisioner "local-exec" {    
    command = "pip install --target='.python_packages/lib/site-packages' -r requirements.txt"
    working_dir = "../${path.module}/blob_storage_trigger"
  }
}

#Uploading to the blob container
resource "azurerm_storage_blob" "storage_blob_function" {
  name                   = "my-function.zip"
  storage_account_name   = "***"
  storage_container_name = "***"
  type                   = "Block"
  source                 = "../${path.module}/blob_storage_trigger.zip"
}

# Create Azure App Service Plan using Consumption pricing
resource azurerm_service_plan "app_service_plan" {
  name                   = "app_service_plan"
  location               = "West Europe"
  resource_group_name    = "***"
  os_type                = "Linux"
  sku_name               = "Y1"
}

resource "azurerm_function_app" "blurring_fn_app" {
  name                = "calinfntest-app-terraform"
  location            = "West Europe"
  resource_group_name = "***"


  storage_account_name       = "***"
  storage_account_access_key = "***"
  app_service_plan_id =  azurerm_service_plan.app_service_plan.id

  app_settings = {
    "WEBSITE_RUN_FROM_PACKAGE" = azurerm_storage_blob.storage_blob_function.url
  }
  site_config {}
}

Observations:

The function-app is successfully created, the pip packages are successfully installed inside the .zip package that is uploaded on a blob container within a storage account (I double-checked this step, even in the logs of TerraForm) and the .zip is successfully uploaded to the blob container specified in azurerm_function_app resource.

The terraform apply runs successfully, but when I open the Azure Portal and go the the function app, there is no actual function deployed (no functions available).

However, I can I can see my code appearing in "AppFiles" section as denoted below, but not in the Function section.

How can I solve this problem?

The problem was here :

data "archive_file" "function_zip" {
  type        = "zip"
  source_dir  = "../${path.module}/blob_storage_trigger"
  output_path = "../${path.module}/blob_storage_trigger.zip"
  depends_on = [null_resource.pip]
}

The .zip would need an additional, upper-level folder in order to properly create a nested folder so that the application is correctly deployed.

So the source_dir needs to be like "../${path.module}/upper_level_folder_name", which in essence contains the "blob_storage_trigger" folder.

Eventually, the structure of the deployment must look like:

.zip
   -function_1
           -.zipped_code_for_function_1

   -function_2
           -.zipped_code_for_function_2

My problem was that in .zip I only put .zipped_code_for_function_1.

Consequently, the problem is solved by respecting the structure from above.