Filtering Outlook email using subject and date range

I am trying to filter an email from Outlook Inbox with subject " Daily Water Consumption" and sent today.

The code is working if I filter by subject only.

When I filter by subject and date both I am not getting any result. I am not getting any error.

Public Sub Download_wat()
    
    Dim outlookApp As Outlook.Application 
    Dim outlookInbox As Outlook.MAPIFolder 
    Dim outlookRestrictItems As Outlook.Items 
    Dim outlookLatestItem As Outlook.MailItem 
    Dim outlookAttachment As Outlook.Attachment 
    Dim subjectFilter As String
    Dim flt As String 
    Dim startDate As String 
    Dim endDate As String
    Const senderName As String = "Mech" 
    Dim attachmentName As String  
    
    subjectFilter = "@SQL=" & Chr(34) & "urn:schemas:httpmail:subject" & Chr(34) & " like '%Daily Consumption%'"      
    
    'Create an instance of Outlook
    Set outlookApp = New Outlook.Application
    
    'Get the inbox from Outlook
    Set outlookInbox = outlookApp.GetNamespace("MAPI").GetDefaultFolder(olFolderInbox)
    
    startDate = CStr(Date) & " " & "00:00"  'Date can be replaced with any string Date
    endDate = CStr(Date + 1) & " " & "00:00"  'the same, it should be the previous Date +1
    subjectFilter = "@SQL=urn:schemas:httpmail:subject" & "" & " ci_phrasematch 'Daily Water Consumption'"
    flt = "[Subject] = 'subjectFilter' and [ReceivedTime] >= '" & startDate & "' and  [ReceivedTime] < '" & endDate & "'"
    
    Set outlookRestrictItems = outlookInbox.Items.Restrict(flt)
    
    'Check whether any items were found
    If outlookRestrictItems.Count = 0 Then
        MsgBox "No items were found from " & senderName & "!", vbExclamation
        Exit Sub
    End If
    
    'Sort the filtered items by received time and in descending order
    outlookRestrictItems.Sort Property:="[ReceivedTime]", Descending:=True
    
    'Get the latest item from the filtered and sorted items
    
    Set outlookLatestItem = outlookRestrictItems(1)
    Debug.Print outlookLatestItem.Subject
End Sub

You can filter the filtered subject items rather than concatenating into one filter.

Option Explicit

Public Sub Download_wat()
    
    Dim outlookInbox As Folder

    Dim outlookRestrictItemsSubj As Items
    Dim outlookRestrictItems As Items
    
    Dim outlookLatestItem As Object
    
    ' May not be a mailitem.
    'Dim outlookLatestItem As outlook.MailItem
    
    Dim subjectFilter As String
    Dim timeFilter As String
    
    Dim startDate As String
    Dim endDate As String
    
    'Get the inbox from Outlook
    Set outlookInbox = Session.GetDefaultFolder(olFolderInbox)
    
    startDate = CStr(Date) & " " & "00:00"  'Date can be replaced with any string Date
    Debug.Print " startDate: " & startDate
    
    endDate = CStr(Date + 1) & " " & "00:00"  'the same, it should be the previous Date +1
    Debug.Print " endDate..: " & endDate
    
    'subjectFilter = "@SQL=urn:schemas:httpmail:subject" & "" & " ci_phrasematch 'Daily Water Consumption'"
    subjectFilter = "@SQL=" & Chr(34) & "urn:schemas:httpmail:subject" & Chr(34) & " like '%Daily Water Consumption%'"
    Debug.Print " subjectFilter.: " & subjectFilter
    
    Set outlookRestrictItemsSubj = outlookInbox.Items.Restrict(subjectFilter)
    Debug.Print outlookRestrictItemsSubj.count
    
    timeFilter = "[ReceivedTime] >= '" & startDate & "' and [ReceivedTime] < '" & endDate & "'"
    Debug.Print " timeFilter: " & timeFilter
    
    Set outlookRestrictItems = outlookRestrictItemsSubj.Restrict(timeFilter)
    Debug.Print outlookRestrictItems.count
    
    'Check whether any items were found
    If outlookRestrictItems.count = 0 Then
        MsgBox "No items were found!", vbExclamation
        Exit Sub
    End If
    
    'Sort the filtered items by received time in descending order
    outlookRestrictItems.Sort Property:="[ReceivedTime]", Descending:=True
    
    'Get the latest item from the filtered and sorted items
    Set outlookLatestItem = outlookRestrictItems(1)
    Debug.Print outlookLatestItem.subject
    Debug.Print outlookLatestItem.ReceivedTime
    
End Sub