AS3 - startDrag with inertia or momentum?

Still learning Adobe Animate AS3, so please be kind.
I would like to create a "swipe to delete" type action. Is there any way of adding some inertia or momentum please? When I relaease the object it just stops.
No idea, and for a change Google isn't offering any help.
Any pointers would be awasome.
TIA

import flash.events.Event;
import flash.events.MouseEvent;
import flash.geom.Rectangle;

var savedY:Number = 0;
var delta:Number = 0;
var scrollArea:Number = 0;

stage.addEventListener(MouseEvent.MOUSE_DOWN, startDragging2, true);
stage.addEventListener(MouseEvent.MOUSE_UP, stopDragging2, true);
 
function startDragging2(e:MouseEvent) {
	mcMsg2c.startDrag(false, new Rectangle (-1800,400,1400,00));
}
 
function stopDragging2(e:MouseEvent) {
	mcMsg2c.stopDrag();

		stage.removeEventListener(MouseEvent.MOUSE_DOWN, startDragging2, true);
		stage.removeEventListener(MouseEvent.MOUSE_UP, stopDragging2, true);
		stop();
}

Welcome, the new soul in a pursuit of knowledge.

It is, of course, possible to add any type of easing to an object you drag, you just need something else than built-in startDrag(...) method, it is too simple and not customizable.

So, first of all, let's setup the environment, where your designated object is attracted to a certain point. Like gravity, something like that.

import flash.geom.Point;
import flash.events.Event;
import flash.utils.getTimer;

// I want it to be short.
var M:DisplayObject = mcMsg2c;

// The attractor is placed onto the object, so it doesn't move at start.
var C:Point = new Point(M.x, M.y);

// To keep the current velocity of M.
var V:Point = new Point(0, 0);

// The most precise calculations we can get if we
// take the passing time into the account.
var T:int = getTimer();

// Acceleration and Friction coefficients, respectively.
// Altering those you can balance, tune or dis-balance the system.

// How strong the pull is.
var A:Number = 1;

// How much of the momentum is constantly lost. Must normally be between 0 and 1.
// 0 = no friction, will get out of balance eventually.
// 1 = full friction, all momentum is lost in 1 second.
// 2 = well, it won't hurt you to try and see!
var F:Number = 0.2;

// Let's calculate this simple physics model every frame.
addEventListener(Event.ENTER_FRAME, onFrame);

function onFrame(e:Event):void
{
    // Take the passed time into account.
    var aTime:int = getTimer();
    
    // The time delta from the last call — now in seconds.
    var aDiff:Number = (aTime - T) / 1000;
    
    // Keep the new time.
    T = aTime;
    
    // Calculate acceleration.
    var anAxel:Point = new Point;
    
    anAxel.x = (C.x - M.x) * aDiff * A;
    anAxel.y = (C.y - M.y) * aDiff * A;
    
    // Apply acceleration.
    V.x += anAxel.x;
    V.y += anAxel.y;
    
    // Apply friction.
    V.x *= 1 - F * aDiff;
    V.y *= 1 - F * aDiff;
    
    // Apply the calculated motion.
    M.x += V.x;
    M.y += V.y;
}

What's now left is to drag this virtual point C and let the physics do the rest.

import flash.events.MouseEvent;

stage.addEventListener(MouseEvent.MOUSE_DOWN, onDown);

function onDown(e:MouseEvent):void
{
    // Track the mouse.
    stage.addEventListener(MouseEvent.MOUSE_MOVE, onMove);
    stage.addEventListener(MouseEvent.MOUSE_UP, onUp);
    
    // Initially fix the attractor.
    onMove(null);
}

function onMove(e:MouseEvent):void
{
    // Sync the attractor with the mouse.
    C.x = mouseX;
    C.y = mouseY;
    
    // Here you are free to apply any additional conditions and fix the coordinates.
    // Just remember that stage coordinates and local coordinated might be different.
}

function onUp(e:MouseEvent):void
{
    // Fix the attractor for the last time.
    onMove(null);
    
    // Stop tracking the mouse.
    stage.removeEventListener(MouseEvent.MOUSE_UP, onUp);
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMove);
}

I didn't test that, but the general idea should be correct, I believe you'll figure it from here on. Good luck!

UPD: I don't really understand what do you mean by "continue when you release", but here's a simplified version of the easing, without physics:

import flash.geom.Point;
import flash.events.Event;
import flash.utils.getTimer;

var M:DisplayObject = mcMsg2c;
var C:Point = new Point(M.x, M.y);

var T:int = getTimer();

// Speeding coefficient.
var S:Number = 1;

addEventListener(Event.ENTER_FRAME, onFrame);

function onFrame(e:Event):void
{
    var aTime:int = getTimer();
    var aDiff:Number = (aTime - T) / 1000;
    
    T = aTime;
    
    // The direction vector MC.
    var aDir:Point = new Point(C.x - M.x, C.y - M.y);
    
    // Follow the attractor point.
    M.x += aDir.x * aDiff * S;
    M.y += aDir.y * aDiff * S;
}

This one will give no oscillations, the object just follwos the attractor with easing.