Invalid argument error from open when reading data from a windows program in perl

I am an intermediate user that has been pressed into service to work with routines that monitor program use by getting license manager status reports.
I am using perl on a server that is running Windows Server 2019 Standard V 1809

I am presently having a problem with a new program (based on ones that work) which produces an “Invalid argument” error when it runs the line to get the status.

The lines in the program that I am having trouble with are:

# $command1 = "c:\\Cadence\\LicenseManager\\lmutil.exe lmstat -a -c `c:\\Cadence\\LicenseManager\\license.dat |";
$command1 = '"C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\bin\lmutil" lmstat -a -c "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\innovmet.lic"';

print "Read license status - >$command1<\n\n";
open(STATUS, $command1) || die "Couldn't run $command1: $!\n";

The commented version of the $command1 assignment works from a previous program.
The uncommented version produces "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\bin\lmutil" lmstat -a -c "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\innovmet.lic" which runs perfectly as a command from a command prompt.
The big difference that I can see is that I had to use ‘ so that I could get the quote marks needed to handle the spaces in the directory names. I did not get to specify the directory names.
The uncommented version does not have the pipe in the command. I wanted to be sure that this was not the cause of the problem and it cannot run from the command line with it.

The output that I get from this part of the code is:
> Read license status - >"C:/Program Files/InnovMetric/PolyWorks MS License Server 2022/bin/lmutil" lmstat -a -c "C:/Program Files/InnovMetric/PolyWorks MS License Server 2022/innovmet.lic"<
>
> Couldn't run "C:/Program Files/InnovMetric/PolyWorks MS License Server 2022/bin/lmutil" lmstat -a -c "C:/Program Files/InnovMetric/PolyWorks MS License Server 2022/innovmet.lic": Invalid argument

Anyone have ideas why perl doesn’t like the command line I am asking it to run?

After fixing the code to compile in the original question, I get this when I run it

>perl.exe try.pl
Read license status - >"C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\bin\lmutil" lmstat -a -c "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\innovmet.lic"<

Couldn't run "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\bin\lmutil" lmstat -a -c "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\innovmet.lic": Invalid argument

That matches what you have. As @user20284150 already mentioned, passing open a filename without a trailing | means it will attempt to open the file "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\bin\lmutil" lmstat -a -c "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\innovmet.lic". That file doesn't exist, thus the error. No idea why it gives the unhelpful error though - would have expected it to say No such file or directory.

To show the distinction, here is a quick demo. Firstly doing the equivalent of what you did and run the open without the trailing |

use strict ;
use warnings;

# Not no trailing "|" in the command
my $command1 = 'perl -v';

print "Read license status - >$command1<\n\n";
open(STATUS, $command1) || die "Couldn't run '$command1': $!\n";

while(<STATUS>)
{
    print "GOT --  $_";
}

running gives

>perl.exe try.pl
Read license status - >perl -v<

Couldn't run 'perl -v': No such file or directory

That gives a useful error

Now the same code, but with the trailing | included

use strict ;
use warnings;

# note trailing "|" this time
my $command1 = 'perl -v |';

print "Read license status - >$command1<\n\n";
open(STATUS, $command1) || die "Couldn't run '$command1': $!\n";

while(<STATUS>)
{
    print "GOT --  $_";
}

that gives this output

>perl.exe try.pl
Read license status - >perl -v |<

GOT --  
GOT --  This is perl 5, version 32, subversion 1 (v5.32.1) built for MSWin32-x64-multi-thread
GOT --
GOT --  Copyright 1987-2021, Larry Wall
GOT --
GOT --  Perl may be copied only under the terms of either the Artistic License or the
GOT --  GNU General Public License, which may be found in the Perl 5 source kit.
GOT --
GOT --  Complete documentation for Perl, including FAQ lists, should be found on
GOT --  this system using "man perl" or "perldoc perl".  If you have access to the
GOT --  Internet, point your browser at http://www.perl.org/, the Perl Home Page.
GOT --

You're trying to open a file named "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\bin\lmutil" lmstat -a -c "C:\Program Files\InnovMetric\PolyWorks MS License Server 2022\innovmet.lic" for reading. There's no such file. It's not even a legal file name, thus the Invalid argument error message.

The correct approach:

my $cmd = '...';

open( my $pipe, "-|", $cmd )
   or die( "Can't launch cmd: $!\n" );

...

close( $pipe );
die( "Error closing pipe: $!\n"                   ) if $? == -1;
die( "Child killed by signal ".( $? & 0x7F )."\n" ) if $? & 0x7F;
die( "Child exited with error ".( $? >> 8 )."\n"  ) if $? >> 8;

(@pmqs suggests open( PIPE, "$cmd |" ) instead of open( my $pipe, "-|", $cmd ), but using open with only two arguments is archaïc, and using a global variable for the file handle is a bad practice.)

For example,

use v5.14;
use warnings;

my $cmd = 'perl -v';

open( my $pipe, "-|", $cmd )
   or die( "Can't launch cmd: $!\n" );

while ( <$pipe> ) {
   chomp;
   say "[$_]";
}

close( $pipe );
die( "Error closing pipe: $!\n"                   ) if $? == -1;
die( "Child killed by signal ".( $? & 0x7F )."\n" ) if $? & 0x7F;
die( "Child exited with error ".( $? >> 8 )."\n"  ) if $? >> 8;

>75747203.pl
[]
[This is perl 5, version 32, subversion 1 (v5.32.1) built for MSWin32-x64-multi-thread]
[]
[Copyright 1987-2021, Larry Wall]
[]
[Perl may be copied only under the terms of either the Artistic License or the]
[GNU General Public License, which may be found in the Perl 5 source kit.]
[]
[Complete documentation for Perl, including FAQ lists, should be found on]
[this system using "man perl" or "perldoc perl".  If you have access to the]
[Internet, point your browser at http://www.perl.org/, the Perl Home Page.]
[]