drag and drop files onto the batch file?

I have a script that looks like this :

@Echo off

cd C:\Users\Example\Subexample
for /r "C:\Users\Myname\Downloads" %%v in (*.txt) do idosomething -f "%%v"

pause

this first tells current directory changes to Subexample where idosomething.exe is located
and it does the recursive operation for all text files in Downloads folder. the output file is then saved in the same location with suffix "_new" automatically attached by the program.

now, how can I just drag and drop one or more text files from any directories onto batch file and make it do the same operation? If possible, the batch file should be able to be put in any folder of my liking.

thank you!

Create first a batch file in directory %USERPROFILE% or any other directory of your choice with a file name like ProcessTextFiles.cmd or any other file name of your choice with the following command lines:

<!-- language: lang-none -->

@echo off
setlocal EnableExtensions DisableDelayedExpansion
if not "%~1" == "" goto ProcessArgs

echo %~nx0 must be run with one or more folder paths
echo or with one or more text file names as argument(s).
echo(
pause
goto EndBatch

:ProcessArgs
set "ExeFileName=C:\Full Path\Executable.exe"
for %%I in (%*) do (
    if exist "%%~fI\" (
        echo Processing all .txt files in directory structure beginning from:
        echo "%%~fI"
        for /F "eol=| delims=" %%J in ('dir "%%~fI\*.txt" /A-D-L /B /S 2^>nul') do "%ExeFileName%" -f "%%J"
    ) else if /I "%%~xI" == ".txt" (
        if exist "%%~fI" (
            echo Processing file: "%%~fI"
            "%ExeFileName%" -f "%%~fI"
        ) else (
            echo Skippig not existing file: "%%~fI"
        )
    ) else echo Skipping argument: "%%~I"
)

:EndBatch
endlocal

This batch file executes a short usage help on running it without any argument string like on double clicking on this batch file. The usage help should be extended to describe what this batch file is for and how to use it.

Start next Windows File Explorer and browse to directory %SystemRoot%\System32 (Windows system directory) and click with secondary (usually right) pointing device (mouse) button on the file cmd.exe to open the context menu for the Windows Command Processor which is processing batch files like the above one.

Click with primary (usually left) pointing device button on the item Show more options on Windows 11 and click next on any Windows in submenu Send to on the context menu item Desktop (create shortcut). Then minimize Windows File Explorer window to see your desktop with the new shortcut file with name cmd.exe or cmd.exe - Shortcut depending on version of Windows.

Click with secondary pointing device button on the newly created shortcut file and (after clicking on Show more options on Windows 11) click on context menu item Rename to change the name of the shortcut file to something meaningful. The name of the shortcut file is later the name of a context menu item in context submenu Send to.

Click with secondary pointing device button on the newly created and already renamed shortcut file and click on the context menu item Properties to open Properties dialog window for the shortcut.

Modify the property Target by appending a space character and /D /C "%USERPROFILE%\ProcessTextFiles.cmd"

There should be entered also a meaningful Comment. There can be selected a nice icon displayed later in the context submenu Send to and of course all other properties on the other tabs to whatever you like before closing the dialog window with button OK to save all changed properties and close the window.

Cut the modified shortcut file with <kbd>Ctrl+X</kbd>, restore the Windows File Explorer window, browse to the directory %APPDATA%\Microsoft\Windows\SendTo and paste with <kbd>Ctrl+V</kbd> the shortcut file.

There can be selected in Windows File Explorer (or any other file manager with Explorer context menu support) one or more directories and/or .txt files before opening the context menu with secondary pointing device button and (after clicking on Show more options on Windows 11) clicking in submenu Send to on the context menu item with name of the shortcut file. Then explorer.exe (or any other file manager executable) starts the Windows Command Processor to process the specified batch file with all names of directories and files selected in file manager appended as additional arguments passed by cmd.exe to the batch file.

Please note that there is a command line length limitation which means it is not possible to select thousands of .txt files and process them all with a single execution of the batch file.

The batch file supports also file/folder arguments with relative paths for manual execution from within a command prompt window or for calling it from another batch file with one or more file/folder names.

To understand the commands used and how they work, open a command prompt window, execute there the following commands, and read the displayed help pages for each command, entirely and carefully.

• call /? ... explains %~nx0 and %*
• dir /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• pause /?
• set /?
• setlocal /?

Not sure I got your question right, but this approach would allow processing one or more filenames dragged onto the .bat file:

@echo off

cd /d C:\Temp

:loop
if exist "%1" (
  echo %1
  shift
  goto loop
)

cd
pause