Opening another excel file and copy the "specific" filtered columns to the current active workbook

Im trying to open another workbook with a filtered columns but every time I run the macro, it only copies 1 visible cell only to my active workbook.

here's the code that I use

Sub SelectAfile()
'Select a file Macro
    Dim FileLocation As String
    Dim LastRow As Long, wsPaste As Worksheet, curr_lrow As Long
    Dim wb As Workbook, ImportWorkbook As Workbook, wsImport As Worksheet
    
    'Open File
    FileLocation = Application.GetOpenFilename
    If FileLocation = "False" Then
        MsgBox "Please select a file.", vbCritical
        Exit Sub
    End If
    
    'Set variables for copy and destination sheets
    Set wb = ActiveWorkbook         'Copy
    Set wsPaste = wb.Worksheets(1)  'Paste
    
    Application.ScreenUpdating = False
    Set ImportWorkbook = Workbooks.Open(Filename:=FileLocation)
    Set wsImport = ImportWorkbook.Worksheets(2)
    
    '1. Find last used row in the copy range based on data in column A
    LastRow = wsImport.Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row 
    '2. Find first blank row in the destination range based on data in column A 
    curr_lrow = wsPaste.Cells(Rows.Count, "A").End(xlUp).Row + 1 'safer than .End(xlDown)...
    
    CopyValues wsImport.Range("A2:A" & LastRow).SpecialCells(xlCellTypeVisible), wsPaste.Range("A" & curr_lrow)
    CopyValues wsImport.Range("C2:C" & LastRow).SpecialCells(xlCellTypeVisible), wsPaste.Range("b" & curr_lrow)
    CopyValues wsImport.Range("D2:D" & LastRow).SpecialCells(xlCellTypeVisible), wsPaste.Range("c" & curr_lrow)
    
End Sub

Sub CopyValues(rngFrom As Range, rngTo As Range) 'Continuation from SelectAfile
    With rngFrom
        rngTo.Resize(.Rows.Count, .Columns.Count).Value = .Value
    End With
End Sub

I tried some other codes like looping through each visible cells but it takes too long when the data is big

If you place a breakpoint in your CopyValues function and examine rngFrom.Address you will notice that it is a comma-separated "list" of ranges, not just a single range.
You need to deal with all of those Areas individually e.g. something like this might work for you

Sub CopyValues(rngFrom As Range, rngTo As Range) 'Continuation from SelectAfile
    Dim x As Variant
    With rngFrom
        For Each x In rngFrom.Areas
            rngTo.Resize(x.Rows.Count, x.Columns.Count).Value = x.Value
            **Set rngTo = rngTo.Offset(x.Rows.Count, 0)**
        Next
    End With
End Sub