How can I use with the Daynamic sql for update table in oracle

I am new in oracle .I create a table with columns and insert data into table
my code is :

create table Tbl_Job_Desc 
(
id int,
name varchar2(50),
family varchar2(50),
jobname varchar2(50)
)


INSERT INTO Tbl_Job_Desc (id,name,family,jobname )VALUES (1,'negar','GHANBARIAN','PROGRAMMER');
INSERT INTO Tbl_Job_Desc (id,name,family,jobname )VALUES (2,'ZAHRA','GHANBARIAN','STUDENT');
INSERT INTO Tbl_Job_Desc (id,name,family,jobname )VALUES (3,'SHIRIN','SAEEDI','NURSE');
INSERT INTO Tbl_Job_Desc (id,name,family,jobname )VALUES (4,'FATEME','GHASEMI','TEACHER');
INSERT INTO Tbl_Job_Desc (id,name,family,jobname )VALUES (5,'mohammad','AZADI','PROGRAMMER');

I want Write a procedure that takes an input from the user and produces an update statement as follows.
update Tbl_Job_Desc set Jobname='newjob'
I write this procedure but I get error ,please take a look my procedure and help me .
my procedure is :

CREATE OR replace PROCEDURE Ds_sampleTest (
                                      newjob  IN VARCHAR2
                                     
                                       )
IS
  newjob VARCHAR2(200);
  query  VARCHAR2(1000);
BEGIN

    query := 'update Tbl_Job_Desc set Jobname='||newjob' ;
    
    dbms_output.Put_line(query);

     EXECUTE IMMEDIATE query;
END;


-- Run the Procedure
CL scr
SET serveroutput ON
BEGIN
    Ds_sample( 'doctor');

    COMMIT;
END;

I want Write a procedure that takes an input from the user and produces an update statement as follows.
update Tbl_Job_Desc set Jobname='newjob'
my error is : PLS-00103

Do not use dynamic SQL if you do not need to:

CREATE PROCEDURE Ds_sampleTest (
  newjob IN Tbl_Job_Desc.Jobname%TYPE
)
IS
BEGIN
  update Tbl_Job_Desc
  set Jobname = newjob;
END;
/

(And do not create local variables that shadow the procedure's parameters.)

Then:

CL scr
SET serveroutput ON

BEGIN
    Ds_sampleTest( 'doctor');
    COMMIT;
END;
/

If you must use dynamic SQL (you do not need to so you should not) then use bind variables rather than string concatenation when you are passing values:

CREATE OR replace PROCEDURE Ds_sampleTest (
  newjob IN Tbl_Job_Desc.Jobname%TYPE
)
IS
  query VARCHAR2(1000);
BEGIN
  query := 'update Tbl_Job_Desc set Jobname = :1';
  dbms_output.Put_line(query);
  EXECUTE IMMEDIATE query USING newjob;
END;
/

fiddle

Adding the error message you are getting to your question would be helpful.

If there are no errors posting your code, then I think your error is related to this part of your code:

query := 'update Tbl_Job_Desc set Jobname='||newjob' ;

In this case, if you want to add quotes to the text, you need to double quote your quotes in the text, the correct code in your example is:

query := 'update Tbl_Job_Desc set Jobname='''||newjob||'''' ;

This will save query as:

update Tbl_Job_Desc set Jobname='your_newjob'

So, whenever you want to add quotes to your text, you need to make them double.
If you want a quote in the middle of your text, you write:

my_text := 'My text with '' quote'

If you want a quote at the beginning or end of your text, you put a double quote, and then the quote to begin or end your text:

my_text := '''There''s a quote at the beginning'

If you want to concatenate a quote to a text, then you need to put the normal quotes at the beginning and end of the text and the double quote, which makes for four consecutive quotes:

my_text := '''' || 'I''m concatenating a quote at the beginning'

OK, so the problem is you are getting this error message when you try to compile your procedure:

Errors: PROCEDURE DS_SAMPLETEST
Line/Col: 0/0 PL/SQL: Compilation unit analysis terminated
Line/Col: 1/1 PLS-00410: duplicate fields in RECORD,TABLE or argument list are not permitted

The error says that you have declared newjob as an IN argument of your procedure but you are at the same time declaring a variable in your procedure with the same name:

newjob VARCHAR2(200);

That it is not allowed, you can delete this line in the declaration, you have declared newjob as IN parameter, or if for some other reason you need to have another variable with the same value as the IN parameter, you use another name, something like this:

v_newjob VARCHAR2(200) := newjob;