ALP program to display characters in between two horizontal lines of 50 pixels long in different colors in the middle of PAGE-2 of a graphics display

QUESTION
Develop an ALP to display your registration number in between two
horizontal lines of 50 pixels long in different colors in the middle of PAGE-2 of a graphics display using BIOS interrupts for writing pixels and characters.

CODE

org 100h

section .data
; The registration number to display
    msg db 'Your Registration Number$'

section .text
; Set up graphics mode
    mov ax, 0013h
    int 10h

; Draw top line
    mov cx, 50
    mov bx, 0
    mov ah, 0Ch             ; Set up to draw pixel
    mov al, 0Fh             ; Set color to white
draw_top_line:
    int 10h
    inc bx                  ; Move to next pixel
    loop draw_top_line      ; Repeat for entire line
    
; Write registration number
    mov si, offset msg
    mov bh, 0
    mov bl, 0Ah             ; Set text color to cyan
    mov ah, 0Eh             ; Set up to write character
    mov cx, 24              ; Set number of characters to write
    mov dx, 140             ; Set starting X position
    mov dh, 90              ; Set starting Y position
print_msg:
    lodsb                   ; Load character from memory
    cmp al, '$'             ; Check for end of string
    je end_print            ; Exit loop if end of string
    int 10h                 ; Write character
    inc dh                  ; Move cursor down
    jmp print_msg           ; Loop to next character
end_print:
    
; Draw bottom line
    mov cx, 50
    mov bx, 1900h           ; Set starting address of bottom line
    mov ah, 0Ch             ; Set up to draw pixel
    mov al, 0Fh             ; Set color to white
draw_bottom_line:
    int 10h
    add bx, 320             ; Move to next row of pixels
    loop draw_bottom_line   ; Repeat for entire line
    
; Clean up and restore text mode
    mov ax, 0003h
    int 10h
    
; Exit program
    mov ah, 4Ch
    int 21h

I'm getting these errors using emu8086:

> (3) illegal instruction: section .data or wrong parameters.
> (7) illegal instruction: section .text or wrong parameters.

What is wrong with this program and how can I fix this?

Short answer

Remove the lines section .data and section .text. You don't need those as the mention org 100h indicates that you are aiming for a .COM executable. Just make sure you place the data below the code like I'm showing below:

ORG 256

  ; Set up graphics mode
  mov  ax, 000Dh
  int  10h

  ...

  ; Exit program
  mov  ah, 4Ch
  int  21h

msg db '123456', 0

Long answer

> display your Registration number in between two horizontal line of 50 pixels long in different color in the middle of PAGE-2 of a graphics display using BIOS interrupts to write pixels and characters

It's ok that you are using the BIOS.WritePixel function 0Ch and the BIOS.Teletype function 0Eh. But didn't you consult the manual to learn about the parameters that these functions require? It is not up to you to provide any odd value in any register that you like! eg. The BIOS.WritePixel function 0Ch expects an X coordinate in the CX register and a Y coordinate in the DX register. Not at all the BX that you seem to be passing. And the BIOS.Teletype function 0Eh does not expect anything in the DL and DH registers, that you fill with some positional information.

> display your Registration number in between two horizontal line of 50 pixels long in different color in the middle of PAGE-2 of a graphics display using BIOS interrupts to write pixels and characters

The task wants you to use a color graphics mode and indeed mode 13h is the 320x200 256-color graphics mode, but the task also mentions to use "PAGE-2" and that is not available for mode 13h.
In order to obey the task description, you have among the legacy video modes a choice between mode 0Dh (320x200 16-color with 8 pages) or mode 0Eh (640x200 16-color with 4 pages).
In the below code snippets, I will be assuming that the video mode will be mode 0Dh.

> display your Registration number in between two horizontal line of 50 pixels long in different color in the middle of PAGE-2 of a graphics display using BIOS interrupts to write pixels and characters

Next is an example of how you draw a horizontal line using BIOS:

; Draw top line
  mov  dx, 95           ; Y
  mov  cx, 135          ; X
  mov  bh, 2            ; Page 2
draw_top_line:
  mov  ax, 0C0Fh        ; AH=0Ch WritePixel, AL=0Fh White
  int  10h
  inc  cx               ; Next X
  cmp  cx, 185
  jb   draw_top_line

> display your Registration number in between two horizontal line of 50 pixels long in different color in the middle of PAGE-2 of a graphics display using BIOS interrupts to write pixels and characters

Because the screen is in a color graphics mode it is possible for the BIOS.Teletype function 0Eh to write in color. However from the looks of it, it seems that you are providing a number of parameters aimed at another BIOS function (WriteString 13h). You can't just mix these.
Next is an example of how you write a message using BIOS:

  ; Write registration number
  mov  si, offset msg
  mov  bx, 020Ah        ; BH=0 Page, BL=10 Cyan
print_msg:
  lodsb                 ; Load character from memory
  cmp  al, 0            ; Check for end of string
  je   end_print
  mov  ah, 0Eh          ; Teletype
  int  10h
  jmp  print_msg
end_print:

Now this Teletype function starts displaying characters from where the cursor is at the moment, and so you will have to position the cursor first with the BIOS.SetCursorPosition function 02h:

  mov  dx, 0C11h        ; DH=12 Row, DL=17 Column
  mov  bh, 2            ; Page
  mov  ah, 02h          ; BIOS.SetCursorPosition
  int  10h

And finally, since all output went to display page 2 (while display page 0 is shown on your screen), it's time to actually switch to display page 2:

  mov  ax, 0502h
  int  10h

And of course, give yourself a chance to see the result before switching back to text video mode. Just wait for the user to press a key:

  mov  ah, 00h
  int  16h
  mov  ax, 0003h
  int  10h
  mov  ah, 4Ch
  int  21h

Final remark: If your emulator doesn't support multiple display pages, then keep using page number 0 and complain to your teacher about the non-sense task requirement for emu8086...