n choose k in MIPS Assembly

    .text
	    addi	$v0, $zero, 5
	    syscall
	    add	$a0, $v0, $zero  
	
	    addi	$v0, $zero, 5
	    syscall
	    add	$a1, $v0, $zero  #call choose function
	    jal	choose

	    add	$a0, $v0, $zero  #print result
	    addi	$v0, $zero, 1
	    syscall

	    addi	$v0, $zero, 10   #exit program
	    syscall

choose:
    	addi 	$sp, $sp, -16    
    	sw 	$ra, 0($sp)        # save the return address on the stack
    	sw 	$s0, 4($sp)        # save s0 on the stack
    	sw 	$a0, 8($sp)        # save n on the stack
    	sw 	$a1, 12($sp)       # save k on the stack

    	slt 	$t0, $a0, $a1     # check if n < k
    	beq 	$t0, $1, choose_end
    	beq 	$a0, $0, choose_one   # check if n == 0 or k == 0
    	beq 	$a1, $0, choose_one

    	addi 	$a0, $a0, -1     # calculate choose(n-1, k-1)
    	addi 	$a1, $a1, -1
    	jal 	choose
    	move 	$s0, $v0

    	addi 	$a0, $a0, 1     # calculate choose(n-1, k)
    	jal 	choose
    	add 	$v0, $s0, $v0     # add val1 and val2

    	j 	choose_end

choose_one:
    	li 	$v0, 1             # return 1
    	j 	choose_end

choose_end:
    	lw 	$ra, 0($sp)        # restore the return address
    	lw 	$s0, 4($sp)        # restore s0
    	addi 	$sp, $sp, 16     # deallocate space from stack
    	jr 	$ra                # return to caller

Idk what's wrong with this code

I enter 2 and 3 and the result is 4

• beq $t0, $1, choose_end is not comparing $t0 to a constant value 1. This instruction is comparing $t0 with register No.1, which is a register $at, which is reserved for an assembler. You should use bne $t0, $0, choose_end instead to check the comparision result.
• You saved n and k to the stack, but never restored them. Some code to restore them should be added after the first recursive function call.
• You forgot to set the return value, which should be 0, for the n < k case.

Fixed code:

choose:
        addi    $sp, $sp, -16
        sw  $ra, 0($sp)        # save the return address on the stack
        sw  $s0, 4($sp)        # save s0 on the stack
        sw  $a0, 8($sp)        # save n on the stack
        sw  $a1, 12($sp)       # save k on the stack

        slt     $t0, $a0, $a1     # check if n < k
        # use proper comparision, and go to setting the return value
        #beq     $t0, $1, choose_end
        bne     $t0, $0, choose_zero
        beq     $a0, $0, choose_one   # check if n == 0 or k == 0
        beq     $a1, $0, choose_one

        addi    $a0, $a0, -1     # calculate choose(n-1, k-1)
        addi    $a1, $a1, -1
        jal     choose
        move    $s0, $v0

        # restore n and k
        lw $a0, 8($sp)
        lw $a1, 12($sp)
        # n-1, not n+1, should be used for the next call
        #addi    $a0, $a0, 1     # calculate choose(n-1, k)
        addi    $a0, $a0, -1     # calculate choose(n-1, k)
        jal     choose
        add     $v0, $s0, $v0     # add val1 and val2

        j   choose_end

choose_one:
        li  $v0, 1             # return 1
        j   choose_end

        # set the return value for n < k case
choose_zero:
        li $v0, 0

choose_end:
        lw  $ra, 0($sp)        # restore the return address
        lw  $s0, 4($sp)        # restore s0
        addi    $sp, $sp, 16     # deallocate space from stack
        jr  $ra                # return to caller