why does my number comparing alway become true?

Whenever I run the script, even when the time is under 12:03 it always runs as if the time was over 12:03, And I don't understand why. I wanted to compare the time of day to a set time for an automatic shutdown, but it always returns the time as over my set clock, even when it isn't.

Here is the code:

@echo off
timeout /t 30
:RunAgain
set HH=12
set MM=03

set ThisHour=%TIME:~0,2%
set ThisMinute=%TIME:~3,2%

echo time: %ThisHour%:%ThisMinute%

if ThisHour GEQ HH (
	echo Hour is over %HH%
	if ThisMinute GEQ MM (
		goto Shutdown
		
	) ELSE (
		echo time is under %HH%:%MM%
		timeout /t 30
		goto RunAgain )
) ELSE (
	echo time is under %HH%:%MM%
	timeout /t 30
	goto RunAgain )

:Shutdown
echo Shutting down
pause

The issue here is that the variables are not being correctly passed to the IF statement.

When passing them to the IF, you should add % around the variable names.

It is recommended to use %SystemRoot%\System32\timeout.exe instead of just timeout to avoid that the cmd.exe process has to make multiple file system accesses to find this executable.

You can change the script to:

@echo off
set HH=12
set MM=03

:RunAgain
%SystemRoot%\System32\timeout.exe /t 30
set ThisHour=%TIME:~0,2%
set ThisMinute=%TIME:~3,2%

echo time: %ThisHour%:%ThisMinute%

if "%ThisHour%" GTR "%HH%" echo Hour is over %HH%& goto Shutdown
if "%ThisHour%" == "%HH%" if "%ThisMinute%" GEQ "%MM%" echo Hour is over %HH%& goto Shutdown
echo time is under %HH%:%MM%& goto RunAgain

:Shutdown
echo Shutting down
pause

After doing these changes, the script works as intended.

Script output for under 12:

Waiting for 29 seconds, press a key to continue ...
time: 10:12
time is under 12:03

Waiting for 22 seconds, press a key to continue ...

Script output for over 12:

Waiting for 28 seconds, press a key to continue ...
time: 22:14
Hour is over 12
Shutting down
Press any key to continue . . .

EDIT: Thanks for the comments and corrections