How to look up an arbitrary user's Full Name OR Email address from their Active Directory username in VBA?

I have a list of Active Directory (AD) usernames, retrieved from a server log, representing colleagues who are using software they shouldn't be.

I need to look up, from the AD, their email address or full name, if email address is not possible/reliable, to contact those users.

A tool I have, that gathers the list of usernames from the server logs, is in Excel, thus VBA. I ideally need a solution that works from VBA.

Is there any way to pass an arbitrary AD username, not the current user, and return either the FullName or email address from the AD?

This should be possible in principle, because it is trivial to do in Python using win32net.NetUserGetInfo - so the underlying API must be there.

I can achieve what I need in CMD as well, with the line:

net user %userid% /DOMAIN | find /I "Full name"

Is it possible to call the above line from within VBA (without high risk of corporate antivirus blocking it, because this has happened before when spawning hidden CMD shells from VBA)?

I have solved this in a fairly inelegant way, so am open to better answers, but I have done it by a combination of calling "net user" directly using CMD.exe (from VBA using Shell) and then another SO answer for parsing the output from that Shell command from STDOUT (https://stackoverflow.com/questions/2784367/capture-output-value-from-a-shell-command-in-vba).

The important bits of my code are, in my main VBA sheet (gives you context for 'Me') code:

' Note d_offenders is a dictionary of AD usernames (the value stored is a list of software they have open, so not relevant to this solution)
Dim key As Variant
For Each key In d_offenders.Keys
    Me.Cells(start_row + i, output_col).Value2 = key
    Me.Cells(start_row + i, output_col + 1).Value2 = get_name(CStr(key))
    Me.Cells(start_row + i, output_col + 2).Value2 = d_offenders(key)
    i = i + 1
Next key

Then I use the following two functions to define how the full name is retrieved:

Private Function get_name(uname As String) As String
    Dim res As String
    res = ShellRun("cmd.exe /C net user " & uname & " /DOMAIN | find /I ""Full name""")
    If res > vbNullString Then get_name = Right(res, Len(res) - 29) Else get_name = "Not found."
End Function

Public Function ShellRun(sCmd As String) As String

    'Run a shell command, returning the output as a string

    Dim oShell As Object
    On Error GoTo errHandler
    Set oShell = CreateObject("WScript.Shell")

    'run command
    Dim oExec As Object
    Dim oOutput As Object
    Set oExec = oShell.Exec(sCmd)
    Set oOutput = oExec.StdOut

    'handle the results as they are written to and read from the StdOut object
    Dim s As String
    Dim sLine As String
    While Not oOutput.AtEndOfStream
        sLine = oOutput.ReadLine
        If sLine <> vbNullString Then s = s & sLine & vbCrLf
    Wend

    ShellRun = s
    Exit Function
errHandler:
    ShellRun = vbNullString
End Function

As I said, slightly clunky with the (temporary) CMD windows popping up, but it works and I end up with a list of:

• usernames
• their full name from AD
• the software packages they have open