SAS catalog: file extraction

Is there a way to extract the contents of a sas catalog into plain text files?

One could open the catalog in base sas and copy stuff manually but this seems extremly cumbersome.

You can extract catalog content to a file with the catalog filename access method.

1. Run proc catalog and create an output dataset to identify the catalog entries. Let's create a sample dataset that will be stored in a SAS catalog and then view the entry:

Code:

data _null_;
   file 'work.mycat.data.catams' catalog;

   do i = 1 to 10;
       put i;
   end;
run;

proc catalog cat=sasmacr;
    contents out=contents;
run;

2. Open the contents dataset. You'll see four important variables: libname, memname, name, and type. You can access the contents of each catalog with the dot-separated string: libname.memname.name.type. In this case, we're going to extract work.mycat.data.catams.

3. Use the following data step code to write the contents to an external file:

Code:

data _null_;
   infile 'work.mycat.data.catams' catalog;
   file '/location/contents.txt';
   input;
   put _INFILE_;
run;

Check contents.txt and you should see the numbers 1-10.

Now let's generalize this for many catalogs. The following macro will read all the entries in a catalog and output their contents to a dynamically generated directory with the name LIBNAME.MEMNAME.NAME.TYPE.txt. Each directory is based off the memname of the entry:

 Location
        |
        |--- MEMNAME1
        |           |--- LIBNAME.MEMNAME1.NAME.TYPE1.txt
        |           |--- LIBNAME.MEMNAME1.NAME.TYPE2.txt
        |           |--- LIBNAME.MEMNAME1.NAME.TYPE3.txt
        |           ...
        |--- MEMNAME2
        |           |--- LIBNAME.MEMNAME2.NAME.TYPE1.txt
        |           |--- LIBNAME.MEMNAME2.NAME.TYPE2.txt
        |           |--- LIBNAME.MEMNAME2.NAME.TYPE3.txt
        ...         ...

When specifying the output directory, be sure to include an ending / if you're on Linux or \ if you're on Windows.

%macro extract_catalog(cat=, outdir=);

    /* Get OS slash */
    %if(&sysscp. = WIN) %then %let _SLASH_ = \;
        %else %let _SLASH_ = /;

    /* Create a directory if it does not exist */
    %let dlcreatedir_orig = %sysfunc(getoption(dlcreatedir));
    options dlcreatedir;

    /* Get all distinct memnames */
    proc sql noprint;
        select distinct memname 
        into :memnames separated by '|'
        from contents
        ;
    quit;

    /* Loop over all memnames */
    %do i = 1 %to %sysfunc(countw(&memnames., |));
        %let memname = %sysfunc(scan(&memnames., &i., |));
        %let out = &outdir.&memname.;

        /* Create a directory if it does not exist */
        libname __temp__ "&out.";

        /* Write content of each entry to a folder */
        data _null_;
            set contents;
            where memname = "&memname.";

            cat_entry = catx('.', libname, memname, name, type);

            call execute(catt(
                "data _null_;
                    infile '", cat_entry, "' catalog;",
                    "file '&out.&_SLASH_", cat_entry, ".txt';
                     input;
                     put _INFILE_;
                 run;"
                )
            );
        run;

        libname __temp__ clear;
    %end;

    options &dlcreatedir_orig.;
%mend;

%extract_catalog(cat=mycat, outdir=/location/);

You can simplify the whole mass using FILEVAR feature of INFILE and FILE.

Example:

Use four level filenames instead of creating a nested folder structure.

data _null_;
  set sashelp.vcatalg;
  where libname = 'SASHELP' and memname like 'AFTOOLS';

* where also objtype in (... list of reasonable textual types ...) ;

  entry4 = catx('.', libname, memname, objname, objtype);
  file4 = 'c:\temp\catdump\' || trim(entry4) || '.txt';

  infile entry catalog filevar=entry4 ;
    file dump  filevar=file4 lrecl=32000;

  input;
  put _infile_;
run;