excel - count if multiple words are in a cell

I have values

 AA,BB,CC
 AA,CC
 AA
 AA,BB
 BB
 BB,CC
 CC
 CC,AA
 CC,BB
 BB,CC,DD

find all cells that have. how do I search for each values.

 AA,BB = 2
 BB,CC = 4

Example

COUNTIFS($A:$A,"*AA*",$A:$A,"*BB*") doesn't seem to work.

You could try this using wildcards * with TEXTBEFORE() & TEXTAFTER()

• Formula used in cell D2

=COUNTIFS(A1:A10,"*"&TEXTBEFORE(C2,",")&"*",A1:A10,"*"&TEXTAFTER(C2,",")&"*")

EDIT

As suggested by Tom Sharpe Sir,

• Formula used in cell D2

=LET(x,TEXTSPLIT(C2,","),y,COUNTA(x),
SUM(--(MMULT(N(ISNUMBER(SEARCH(x,$A$1:$A$10))),SEQUENCE(y,,1,0))=y)))

You could try:

Formula in D2:

=MAP(C2:C5,LAMBDA(z,SUM(MAP(A1:A11,LAMBDA(x,LET(y,TEXTSPLIT(z,,","),N(SUM(N(TEXTSPLIT(x,",")=y))=ROWS(y))))))))

Note: My answer assumes no duplicates in the values in column A:A. e.g.: AA,AA.

How about:

=LET(searchvalues,  C2,
     data,          $A$1:$A$10,
     split,         TEXTSPLIT(searchvalues,","),
     count,         COLUMNS(split),
SUM(
    --(MMULT(
             --ISNUMBER(SEARCH(split,data)),
             SEQUENCE(count,,1,0))
       =count)))

It splits the values you want to search (stored in C2 in my example) into individual values: split

Than split is searched within each row of your data.
This returns TRUE or FALSE wrapped in -- changes TRUE to 1 and FALSE to 0.
This is used within MMULT and this returns the sum of the occurrences of each individual split value. Finally the MMULT result needs to equal the number of splitted search values.
The sum of this being true is the end result.

The following approach considers a variable number of words to search, not just 2 words as in the input sample:

=LET(lk, B1, A, $A$1:$A$11, lks, TEXTSPLIT(lk,, ","),
  byr, BYROW(A, LAMBDA(x,SUM(COUNTIF(x,"*"&lks&"*")))), SUM(N(byr=ROWS(lks))))

It has a caveat that if the word is repeated more than one time per row in the first column, it is counted as 1, as you can see in the following output. This is because of how COUNTIF (or COUNTIFS) works with wildcards (other answers provided using SEARCH produce the same result). If that assumption is ok, then it works. The rest is just to drag the formula down (formula1).

UPDATE: Considering @JvdV's comment, to avoid false positive when the word to search could be a substring of the column A on a given row. Like for example, searching the word AA, in the string: AAA will produce a false positive. The following version avoids it:

=LET(lk, B1, A, $A$1:$A$11, lks, TEXTSPLIT(lk,, ","),
 byr, BYROW(A, LAMBDA(x, SUM(N(TEXTSPLIT(x,",") = lks)))), SUM(N(byr=ROWS(lks))))

Here is the output:

I added intentionally the highlighted cases to test additional situations. Row 11 repeats the word: AA, and BB, but it is counted as 1 in the final result.

The following approach tries to identify the total number of counts considering repetitions of the word in column A (formula2):

=LET(lk, B1, A, $A$1:$A$11, lks, TEXTSPLIT(lk,, ","),
 byr, BYROW(A, LAMBDA(x, LET(match, IFERROR(TOCOL(XMATCH(TEXTSPLIT(x, ","),
 lks),2),0), ux, UNIQUE(match), IF(ROWS(ux) < ROWS(lks), 0,
   MIN(MMULT(TRANSPOSE(N(match = TOROW(ux))), SEQUENCE(ROWS(match),,1,0))))))),
 SUM(byr))

Now we get the following result:

Now we get an additional count for the case of AA, BB.

In formula2, match has the index position as a result of the XMATCH call, we use TOCOL to remove non-found values #N/A. In case no words were found, we use IFERROR to assign the zero value. The IF condition:

IF(ROWS(ux) < ROWS(lks)

Ensures to calculate non-zero counts only if all words were found. We use MMULT to calculate per row the number of repetitions of the lookup words. We take the minimum, to ensure we only consider the scenarios where all the words are present. There could be a situation, where one of the lookup words has more counts than another one, which is why we take the minimum. Therefore we are counting the entire set of lookup words found regardless of the order,

Answer was

COUNTIFS($A:$A,"*"&$C$2&"*",$A:$A,"*"&$C$3&"*")

C2 = AA
C3 = BB