get the subnetid from subnets of type map(object)

I need to fetch the subnetid from azurerm_subnet data resource as subnet is used in dynamic block of azurerm_virtual_network as map(object) type

resource "azurerm_virtual_network" "example" {
  name                = "example-vnet"
  address_space       = ["10.0.0.0/16"]
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name

  dynamic "subnet" {
    for_each = var.subnets
    content {
      name           = subnet.value.name
      address_prefix = subnet.value.address_prefix
      security_group = azurerm_network_security_group.example[subnet.key].id
    }
  }
}

Fetch the second subnetid to attach it to storage account

resource "azurerm_storage_account" "example" {
  count                    = length(var.subnets)
  name                     = "storageaccountname"
  resource_group_name      = azurerm_resource_group.example.name
  location                 = azurerm_resource_group.example.location
  account_tier             = "Standard"
  account_replication_type = "GRS"

  network_rules {
    default_action             = "Deny"
    virtual_network_subnet_ids = ["${data.azurerm_subnet.subnetid.id}"]
  }
}

Please can any one help to solve as i want to declare subnet in azurerm_virtual_network as dynamic block and get the subnet if from the data resource and please find my terraform.tfvars as below

subnets = {
  subnet1 = {
    name           = "subnet1"
    address_prefix = "10.0.0.0/24"
  }
  subnet2 = {
    name           = "subnet2"
    address_prefix = "10.0.1.0/24"
  }
  subnet3 = {
    name           = "subnet3"
    address_prefix = "10.0.2.0/24"
  }
}

IMPORTANT

count = length(var.subnets) in resource "azurerm_storage_account" "example" {} is still there in your question which is logically incorrect as I have stated in the comments.

Answer

With your comments, I am assuming that you want to use id of subnet2 in network_rules of resource "azurerm_storage_account" "example" {}. With your current approach where creating subnets within the virtual network resource you have to use splat expressions and locals to make a map out of the set object and then can directly refer wherever is required.

> While doing referencing even with locals and splat expressions it is still required to use the name of the subnet as it is not possible for terraform to know what you want without any data.

resource "azurerm_virtual_network" "example" {
  name                = "example-vnet"
  address_space       = ["10.0.0.0/16"]
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name

  dynamic "subnet" {
    for_each = var.subnets

    content {
      name           = subnet.value.name
      address_prefix = subnet.value.address_prefix
      # security_group = azurerm_network_security_group.example[subnet.key].id ## I have ignored it as no relevant code is shared### 
    }
  }
}

locals {
  subnets = { for subnet in azurerm_virtual_network.example.subnet : subnet.name => subnet }
}

resource "azurerm_storage_account" "example" {
  #count                    = length(var.subnets) ## Removed it too as logically incorrect with the current code ##
  name                     = "storageaccountname"
  resource_group_name      = azurerm_resource_group.example.name
  location                 = azurerm_resource_group.example.location
  account_tier             = "Standard"
  account_replication_type = "GRS"

  network_rules {
    default_action             = "Deny"
    virtual_network_subnet_ids = [local.subnets.subnet2.id]
  }

You do not need a data source when referencing the attributes from one resource/module to another resource/module in the root module.

However, I suggest using azurerm_subnet resource for easier reference in spite of creating subnets in the virtual network resource itself because your might need Microsoft.Storage service_endpoints in your subnets for working with storage account with network_rules.