VB.net need help parsing a substring

I have a value I am capturing from an Http Request

Dim someValue As String = Request.Params("search")

Here is the value of my string:

?MyId1=VALUE1&MyId2=VALUE2&MyBoolen=True

I am trying to capture VALUE2. I tried the below code, but haven't had any success.

If Not String.IsNullOrEmpty(someValue) Then
    Dim x = someValue.Substring(someValue.IndexOf("&"c) + 1)
    If Not String.IsNullOrEmpty(someValue) Then
        Dim y = x.Substring(someValue.IndexOf("="c) + 1)
    End If
End If

How can I do this?

It looks like you're overthinking this. The Request object will let you look up the MyId2 value directly:

Dim MyId2 As String = Request.QueryString("MyId2")

It's also possible this is a nested query string, where what you actually have is something more like this:

/?search=%3FMyId1%3DVALUE1%26MyId2%3DVALUE2%26MyBoolen%3DTrue

This would give you the original string after the runtime URL Decodes the search element. In that case, you should look at the HttpUtility.ParseQueryString() method, rather than trying to do this yourself:

Dim search As String = Request.Params("search")
Dim searchValues As NameValueCollection = HttpUtility.ParseQueryString(search)
Dim MyId2 As String = searchValues("MyId2")

Which could even be written as a one-liner if we really wanted:

Dim MyId2 As String = HttpUtility.ParseQueryString(Request.Params("search"))("MyId2")

But if you really wanted to parse this by hand, one of the nice things about this is everything should be URL-encoded. This means you don't have worry about stray & or = characters as part of the data, and a simple Split() call should be safe:

Dim MyId2 As String = ""
Dim items = someValue.Substring(1).Split("&"c)
For Each item As String In Items 
    Dim parts = item.Split("="c)
    If parts(0) = "MyId2" Then
       MyId2 = parts(1)
       Exit For
    End If
Next

Or

Dim parts() As String = someValue.Substring(1).Split("&"c).
       Select(Function(s) s.Split("="c)).
       FirstOrDefault(Function(p) p(0) = "MyId2")

Dim MyId2 As String = If(parts IsNot Nothing, parts(1), "")