Errorlevel always returns 0 in a for loop with ping command

I am trying to create a batch script that will ping a machine by hostname, save ip and domain to a variable and display the state (ON or OFF).

How can i fix this code so it will display the status correctly?

My code always returns ON even if pc is actually OFF.

@echo off
setlocal ENABLEDELAYEDEXPANSION

set hostname=non-existent-hostname
set domain=UNRESOLVED
set ip=UNRESOLVED

for /f "tokens=2,3 delims= " %%b in ('ping -a -4 -n 1 !hostname! ^| find "Pinging"') do (
    set domain=%%b
    set ip=%%c
)

if errorlevel 1 (
    echo !hostname! !ip! [!domain!] is OFF
) else (
    echo !hostname! !ip! [!domain!] is ON
)

pause

I have another approach using this kind of ping, because my machine is French.

For example, this batch script pings a list of URLs and displays their status (ON/OFF) with different colors.

The URLs are defined in the "URLS" variable.

The script loops through the URLs, formats them using a StringFormat function, gets the IP address of each URL using the "ping" command, and then displays the status of each URL (ON or OFF) with a color using a PSColor function.

<!-- language: lang-bat -->

@echo off
Title Multi-Ping hosts with colors
Set URLS="non-existent-hostname","https://www.google.com","Nothingtotest","https://www.yahoo.com","www.reddit.com",^
"http://www.wikipedia.com","www.stackoverflow.com","www.bing.com","NoBodyHere.com"

setlocal ENABLEDELAYEDEXPANSION
for  %%a in (%URLS%) do (
	Call :StringFormat "%%~a"
	set "ip="
	for /f "tokens=2 delims=[]" %%b in ('ping -n 1 !URL!') do set "ip=%%b"
		ping -n 1 !URL!>nul && set "msg=!URL! - !ip! ON" && Call :PSColor "!msg!" Green \n || set "msg=!URL! - !ip! OFF" && Call :PSColor "!msg!" Red \n
)
pause & Exit
::---------------------------------------------------------------------------------
:StringFormat <URL>
(	
	echo Function StringReplace(Str^)
	echo 	Str = Replace(Str,"http://",""^)
	echo	Str = Replace(Str,"https://",""^)
	echo 	StringReplace = str
	echo End Function
	echo wscript.echo StringReplace("%~1"^)
)>"%tmp%\%~n0.vbs"
for /f "delims=" %%a in ('Cscript /nologo "%tmp%\%~n0.vbs"') do ( set "URL=%%~a" )
If Exist "%tmp%\%~n0.vbs" Del "%tmp%\%~n0.vbs"
exit /b
::---------------------------------------------------------------------------------
:PSColor <String> <Color> <NewLine>
If /I [%3] EQU [\n] (
	Powershell Write-Host "`0%~1" -ForegroundColor %2
) Else (
	Powershell Write-Host "`0%~1" -ForegroundColor %2 -NoNewLine
)
Exit /B
 ::---------------------------------------------------------------------------------

I figured it out, thanks everyone for hints.

@echo off
setlocal ENABLEDELAYEDEXPANSION

set hostname=non-existent-hostname
set domain=UNRESOLVED
set ip=UNRESOLVED

for /f "tokens=2,3 delims= " %%b in ('ping -a -4 -n 1 !hostname! ^| find "Pinging"') do (
    set domain=%%b
    set ip=%%c
)

ping -n 1 %hostname% >nul
if %errorlevel% == 0 (
    echo %hostname% %ip% [%domain%] is ON
) else (
    echo %hostname% %ip% [%domain%] is OFF
)

pause