Is there a way to edit values in list after %let in SAS

I created a macro variable: %let hi = ('g', 'c', 'v', 'd'); I
want to put this list in code but need to add %% for each value, looks like this('%g%', '%c%', '%v%', '%d%'). is there a way i can get the result?

I want to have %% because I want to use LIKE in sql.

I assume that your list may have one or more words, so you can use regex to make the change. The pattern is to lazily find any text surrounded by single quotes and replace it with '%...%'.

PRXCHANGE performs a regex substitution. The first parameter is the regex pattern. The next parameter -1 means to perform the change for every match found.

%let hi = ('word1 word2', ' word3 word4 ');

data _null_;
hi = prxchange("s/'(.*?)'/'%$1%'/", -1, "&hi");
call symputx('hi', hi);
run;

%put &=hi;
HI=('%word1 word2%', '% word3 word4 %')

The regex for substitution follows the general structure of s/Pattern/Replacement/. The pattern in this case is to find text and its enclosing single quotes. The simple pattern for that is '.*'. The . means any single character, and the * is a modifier which means any number or none at all. The question mark ? added to the pattern creates a lazy match which means to match the shortest possible string. By default, regex matches are greedy meaning to match the longest possible string, but that causes problems in this case because we have multiple single quotes in our macro var. The parentheses () in the pattern creates a capture group which saves the matching text within the parentheses to a buffer which can be referred to in the replacement.

The replacement part of the regex substitution '%$1%' refers to $1. It is the text in the capture buffer created by the parentheses in the search pattern. That matching text will be wrapped with percents then single quotes. Voila.

The most straight forward way would be loop over the items in the list and build a new list. Dealing with % and commas is a pain in macro code. So perhaps it would be a lot easier to just do it in a data step.

Example;

%let list=('a','b','c');
data _null_;
  length old new word $1000 ;
  old=symget('list');
  do i=1 to countw(old,'( ,)','q');
     word=quote(cats('%',dequote(scan(old,i,'( ,)','q')),'%'),"'");
     new=catx(',',new,word);
  end;
  call symputx('newlist',cats('(',new,')'));
run;
%put &newlist;

Result

379  %put &newlist;
('%a%','%b%','%c%')

Note that a macro variable can be longer than a character variable in a data step. The maximum length in a variable is 32K (32,767) versus 64K for a macro variable.

%nrstr() masks special characters and prevents the macro system from going down a rabbit hole.

At the outset you can make the assignment as follows:

%let hi = %nrstr(%( '%g%' , '%c%' , '%v%' , '%d%' %));

%put NOTE: hi = %superq(hi);

----- Log -----
NOTE: hi = ( '%g%' , '%c%' , '%v%' , '%d%' )