How to Take Lowest Quantity from Child SKUs and set that number to Parent SKU or add

I am currently using =IFERROR(MAP(A2:A1301,LAMBDA(r,MIN(FILTER(B2:B1301,LEFT(A2:A1301,9)=r&":")))),B2:B1301) to find child SKUs' lowest number and applying it to the parent SKU.

However there are some other scenarios and criterias I needed.

BEFORE FORMULA:

Scenarios:

Parent Sku = 0
Child Sku 1 = 0
Child Sku 2 = 1
-------------
Parent Sku -> 0
Not enough parts to be a full item, none is added to parent.

~~~~~~~~~~~~~~~~~~~
Parent Sku = 0
Child Sku 1 = 1
Child Sku 2 = 1
-------------
Parent Sku -> 1
Enough for a full part to be added to parent SKU

~~~~~~~~~~~~~~~~~~~
Parent Sku = 0
Child Sku 1 = 32
Child Sku 2 = 48
-------------
Parent Sku -> 32
Extra of other child sku, but technically can only make 32 full items of the parent SKU

~~~~~~~~~~~~~~~~~~~
Parent Sku = 1
Child Sku 1 = 3
Child Sku 2 = 6
-------------
Parent Sku -> 4
1 Full Parent Sku already exists, 3 of child skus can be made into a full parent sku, add 3+1 to make 4 total

~~~~~~~~~~~~~~~~~~~
Parent Sku = 7
Child Sku 1 = 5
Child Sku 2 = 4
-------------
Parent Sku -> 7
Possible discrepancy in database but if parent SKU ends up being higher than every child sku, stays the same.

How could I apply all these scenarios into 1 formula at most? I'm using excel 365.

Following the logic mentioned in the comment section of the question, we can apply it as follows:

=LET(sku, A2:A21, qty, B2:B21, isChild, ISNUMBER(SEARCH(":",sku)),
 children, FILTER(sku, isChild), parent, FILTER(sku, NOT(isChild)),
 npQty, MAP(parent, LAMBDA(p, LET(pQty, XLOOKUP(p, sku, qty),
  cQty, FILTER(qty, (ISNUMBER(SEARCH(p,sku))) * (isChild),""),
   IF(@cQty="", pQty, IF(pQty > MIN(cQty), pQty, pQty + MIN(cQty)))))),
 HSTACK(parent, npQty))

Here is the output:

Highlighted in yellow a value that was changed in order to have children (it seems a mistake from the input data). In green a value that doesn't have children.

The name isChild, identifies rows that are children by finding the : token. Based on that we can identify parent and children via FILTER. We use MAP to iterate over each parent(p) and implement the logic for the new parent quantity (npQty). The name cQty, has the quantities of the children for a given parent (p). We cover the case, for a given parent (p) there are no children, as in the case of 31004001. For this case the FILTER function returns "" so the parent quantity remains the same. If there are children, we build the logic to modify the quantity.

If you want to return just thew new quantities (in case it changes, otherwise the same quantity) for each input data, you can use the following formula instead:

=LET(skus, A2:A21, qtys, B2:B21, isChild, ISNUMBER(SEARCH(":",skus)),
 MAP(skus, qtys, LAMBDA(sku,qty,
 IF(@FILTER(qtys, (skus=sku) * NOT(isChild),"")<>"",
  LET(cQty, FILTER(qtys, (ISNUMBER(SEARCH(sku,skus))) * (isChild),""),
   IF(@cQty="", qty, IF(qty > MIN(cQty), qty, qty + MIN(cQty)))), qty))))