auto scale azure spring app URI with terraform

I need enable auto scale for an spring app hosted by spring app services.I am used below terraform code.

resource "azurerm_monitor_autoscale_setting" "spring_apps_app_carrier_events" {
  name                = "default_auto_scale"
  enabled             = true
  resource_group_name = module.rg.resource_group_name
  location            = module.rg.resource_group_location
  target_resource_id  = module.spring_apps_app_carrier_events.app_identities[0].principal_id

  profile {
    name = "defaultProfile"

    capacity {
      default = 1
      minimum = 1
      maximum = 2
    }

It return errors:

Error: Can not parse "target_resource_id" as a resource id: Cannot parse Azure ID: parse "290dc6bd-1895-4e52-bac2-a34e63a138a9": invalid URI for request

It seems it need a uri. May u know how can I get the uri of a spring app?

Thanks in advance

I tried to reproduce the same in my environment.

Received the same error:

│ Error: Can not parse "target_resource_id" as a resource id: Cannot parse Azure ID: parse "xxxxx": invalid URI for request
│   with azurerm_monitor_autoscale_setting.spring_apps_app_carrier_events,

The target_resource_id should not be in just number id form,

It has to be something like /subscriptions/xxxxxc/resourceGroups/<myrg>/providers/Microsoft.xxx/xx/sxx

In your case,

target_resource_id  = module.spring_apps_app_carrier_events.app_identities[0].principal_id

gives the principal Id which is in “23434354544466” format which is not correct.

I tried below code with targetid being, resourceId : /subscriptions/xxx/resourceGroups/ <myrg>/providers/Microsoft.AppPlatform/spring/springcloudappkavya/apps/kaexamplspringcloudapp/deployments/kavyadeploy1

Code:

resource "azurerm_spring_cloud_service" "example" {
name                = "springcloudappkavya"
location            =data.azurerm_resource_group.example.location
resource_group_name = data.azurerm_resource_group.example.name
sku_name            = "S0"
config_server_git_setting {
uri          = "https://github.com/Azure-Samples/piggymetrics"
label        = "config"
search_paths = ["dir1", "dir2"]
}
trace {
connection_string = azurerm_application_insights.example.connection_string
sample_rate       = 10.0
}
tags = {
Env = "staging"
}
}
resource "azurerm_spring_cloud_app" "example" {
name                = "kaexamplspringcloudapp"
resource_group_name = data.azurerm_resource_group.example.name
service_name        = azurerm_spring_cloud_service.example.name
identity {
type = "SystemAssigned"
}
}
resource "azurerm_spring_cloud_java_deployment" "test" {
name                = "kavyadeploy1"
spring_cloud_app_id = azurerm_spring_cloud_app.example.id
instance_count      = 2
jvm_options         = "-XX:+PrintGC"
quota {
cpu    = "2"
memory = "4Gi"
}
runtime_version = "Java_11"
environment_variables = {
"Foo" : "Bar"
"Env" : "Staging"
}
}
resource "azurerm_monitor_autoscale_setting" "spring_apps_app_carrier_events" {
name                = "default_auto_scale"
enabled             = true
resource_group_name = data.azurerm_resource_group.example.name
location            = data.azurerm_resource_group.example.location
target_resource_id  = azurerm_spring_cloud_java_deployment.test.id
// target_resource_id  = .spring_apps_app_carrier_events.app_identities[0].principal_id
// target_resource_id  =  "18xxxxxe2"
profile {
name = "metricRules"
capacity {
default = 1
minimum = 1
maximum = 2
}
rule {
metric_trigger {
dimensions {
name     = "AppName"
operator = "Equals"
values   = [azurerm_spring_cloud_app.example.name]
}
dimensions {
name     = "Deployment"
operator = "Equals"
values   = [azurerm_spring_cloud_java_deployment.test.name]
}
metric_name        = "AppCpuUsage"
metric_namespace   = "microsoft.appplatform/spring"
metric_resource_id = azurerm_spring_cloud_service.example.id
time_grain         = "PT1M"
statistic          = "Average"
time_window        = "PT5M"
time_aggregation   = "Average"
operator           = "GreaterThan"
threshold          = 75
}
scale_action {
direction = "Increase"
type      = "ChangeCount"
value     = 1
cooldown  = "PT1M"
}
}
}
}

Could execute without errors.

Portal view of Autoscale settings for spring apps.

Reference : An Azure Spring Cloud Update: Managed Virtual Network and Autoscale are now generally available in Azure Spring Cloud