Easy initialisation of empty containers

Consider the following code.

struct MyType
    data::Dict{Int, Float64}
end
MyType() = MyType(Dict{Int, Float64}())

Having to repeat the type of data is a bit clumsy, and the problem gets out of hand very quickly if you have more variables and/or your types get more complicated. Can I avoid this?

If the type in question is default-constructible (i.e., it has a no-args constructor), you can use the following trick.

struct Default; end
Base.convert(::Type{T}, ::Default) where T = T()
struct MyType
    data::Dict{Int, Float64}
end
MyType() = MyType(Default())

You can do:

Base.@kwdef struct MyType
    data::Dict{Int, Float64} = Dict{Int, Float64}()
end

And now you can just write MyType():

julia> MyType()
MyType(Dict{Int64, Float64}())

I personally more like the package Parameters which is additionally affecting how struct is displayed:

using Parameters 
@with_kw struct MyType
    data::Dict{Int, Float64} = Dict{Int, Float64}()
end

And now in REPL you can see:

julia> MyType()
MyType
  data: Dict{Int64, Float64}

The following hack-ish method works (as of Julia 1.8):

MyType() = MyType((t() for t in MyType.types)...)

It doesn't include Int or Float64, so it passes OP conditions. And also, it generalizes to types with many fields, and complex ones because it is essentially recursive.