SAS finding overlapping dates and add a flag

I have a dataset at id level with some overlapping dates. All I need to find those rows and add an identifier to count the number overlapping records.

   Data:
          ID     ITEM      StrDate             EndDate
          1001   A121       02/01/2022        02/15/2022
          1001   B121       03/10/2022        03/10/2022
          1002   C121       02/01/2022        02/10/2022
          1002   D121       02/05/2022        02/15/2022
          1003   E121       03/10/2022        03/21/2022
          1003   F121       03/12/2022        03/21/2022
          1004   G121       01/12/2022        01/14/2022

Below is the Result that I am expecting

   Want:
          ID     ITEM      StrDate             EndDate             Indicator
          1001   A121       02/01/2022        02/15/2022              N
          1001   B121       03/10/2022        03/10/2022              N
          1002   C121       02/01/2022        02/10/2022              Y
          1002   D121       02/05/2022        02/15/2022              Y
          1003   E121       03/10/2022        03/21/2022              Y
          1003   F121       03/12/2022        03/21/2022              Y
          1004   G121       01/12/2022        01/14/2022              N

I tried sorting the data first on StrDate and EndDate

            Proc sort data=Data; by ID StrDate EndDate;run;

Then I tried using lag function to find the same id and subtract the dates but I figured that's not the correct way of doing.

I appreciate your help here. thanks

SAS Date values are integers that can be used as an index into a tracking array. This technique is called a direct-index search.

Example:

A double DOW solution can be coded to find the overlapping records. The first loop flags dates in use and the second loop evaluates the range for an overlap by finding a flag via direct-index.

data have;
input ID ITEM $ StrDate EndDate;
attrib strdate enddate format=mmddyy10. informat=mmddyy10.;
datalines;
 1001 A121 02/01/2022 02/15/2022
 1001 B121 03/10/2022 03/10/2022
 1002 C121 02/01/2022 02/10/2022
 1002 D121 02/05/2022 02/15/2022
 1003 E121 03/10/2022 03/21/2022
 1003 F121 03/12/2022 03/21/2022
 1004 G121 01/12/2022 01/14/2022
;

data want;
  array tracker(100000) _temporary_ ;

  do _n_ = 1 by 1 until (last.id);
    set have;
    by id;
    do _i_ = strdate to enddate;
      tracker(_i_) + 1;              /* flag date using direct-index */
    end;
  end;

  do _n_ = 1 to _n_;
    set have;

    /* no overlap would mean no dates in range would find a flag set */
    /* and loop would exit with _i_ > enddate */
    do _i_ = strdate to enddate while (tracker(_i_) = 1);
    end;

    length overlap_indicator $1; 
    overlap_indicator = ifc (_i_ > enddate, 'N', 'Y');
    output;
  end;

  call missing (of tracker(*));
  drop _: ;
run;

Extend, count and remerge, this is my thought.

*An extra observation added to ID 1002;
data have;
  input ID $ ITEM $ StrDate mmddyy10. +1 EndDate mmddyy10.;
  format StrDate EndDate mmddyy10.;
  cards;
  1001 A121 02/01/2022 02/15/2022
  1001 B121 03/10/2022 03/10/2022
  1002 C121 02/01/2022 02/10/2022
  1002 D121 02/05/2022 02/15/2022
  1002 D121 03/05/2022 03/15/2022
  1003 E121 03/10/2022 03/21/2022
  1003 F121 03/12/2022 03/21/2022
  1004 G121 01/12/2022 01/14/2022
 ;
run;

*Extend;
data middle;
  set have;
  do date=StrDate to EndDate;
    output;
  end;
run;

*Count and remerge;
proc sql noprint;
  create table want as 
  select distinct a.*, ifc(b.count and a.StrDate<=b.date<=a.EndDate,'Y','N') as Indicator
  from have as a
  left join (
    select id, date, count(date) as count from middle
    group by id, date
    having count>1
  ) as b on a.id=b.id
  ;
quit;

By the way, if not all records overlapping in dates of one ID but you want to flag all of them out, you need to modify table lookup condition by removing the a.StrDate<=b.date<=a.EndDate.

Simple overlap logic:

proc sql;
create table want as
select
    a.*,
    /* simple overlap logic  */
    case
        when a.strdate <= b.strdate & a.enddate >= b.strdate then 'Y'
        when b.strdate < a.strdate & b.enddate >= a.strdate then 'Y'
        else 'N'
        end as overlap
from
    have  a
    left join
    have  b
        on a.id = b.id         /* join on same ids      */
        and a.item <> b.item   /* but not the same item */
;
quit;

Result:

ID	ITEM	StrDate	EndDate	overlap
1001	B121	03/10/2022	03/10/2022	N
1001	A121	02/01/2022	02/15/2022	N
1002	D121	02/05/2022	02/15/2022	Y
1002	C121	02/01/2022	02/10/2022	Y
1003	E121	03/10/2022	03/21/2022	Y
1003	F121	03/12/2022	03/21/2022	Y
1004	G121	01/12/2022	01/14/2022	N

Overlap occurs if StartA <= StartB when:

StartA          EndA>=StartB
   |-------------|
             |---------
          StartB