How can I count and show largest duplicate from a list in Google Sheets?

I am rather new to Excel (or SQL), and I was wondering how I could count and print the largest duplicate from a list.

Ex.: Lets say you have a list of authors:

Chris Rylander
Charles Soule
Justina Ireland
Claudia Gray
Cavan Scott
Multiple
Cavan Scott
Cavan Scott
Cavan Scott
Cavan Scott
Daniel José Older
Cavan Scott
Multiple
Multiple
Justina Ireland
Cavan Scott
Justina Ireland
Claudia Gray
Multiple
Daniel José Older
Cavan Scott
Cavan Scott
Shima Shinya

As you can see there are a lot of duplicates.
I would like to somehow extract the most used author from that list and the least used author from that list.

So the end results would be like this:
Most used author: Cavan Scott
Least used author: Shima Shinya

Could anyone help me with this problem please?

I tried with Count, Countif, but it returned numbers. Unfortunately thats the extend of my knowledge of google sheets.

Within Sheets, you can try:

=LAMBDA(x,y,{"Most Used Author";FILTER(x,y=max(y));IFERROR(1/0);"Least Used Author";FILTER(x,y=min(y))})(UNIQUE(FILTER(A:A,A:A<>"")),INDEX(LAMBDA(z,COUNTIF(A:A,z))(UNIQUE(FILTER(A:A,A:A<>"")))))

• I have 3 authors coming under Least used whilst you kinda mentioned just one!

formula if wish to see the author+count(max, min)

=LAMBDA(x,y,REDUCE({"Author","Count"},SEQUENCE(2),LAMBDA(a,c,{a;FILTER({x,y},y=INDEX({max(y);min(y)},c))})))(UNIQUE(FILTER(A:A,A:A<>"")),INDEX(LAMBDA(z,COUNTIF(A:A,z))(UNIQUE(FILTER(A:A,A:A<>"")))))

USING QUERY:

Most Used

=QUERY(QUERY(A:A,"SELECT A, COUNT(A) WHERE A<>'' GROUP BY A ORDER BY COUNT(A) DESC LIMIT 1 LABEL COUNT(A)''"),"SELECT Col1")

Least Used

=QUERY(QUERY(A:A,"SELECT A, COUNT(A) WHERE A<>'' GROUP BY A ORDER BY COUNT(A) LIMIT 1 LABEL COUNT(A)''"),"SELECT Col1")

Incase the new functions have rolled out for you, use:

Most Used

=LET(a,A:A,z,INDEX(COUNTIF(a,a)),+FILTER(a,z=max(z)))

Least Used

=LET(a,A:A,z,INDEX(COUNTIF(a,a)),+FILTER(a,z=MIN(FILTER(z,z>0))))

I would would solve in the following way:

1. Find unique values =unique(range)
2. Count the occurrence =contif(unique_values,list_unique)
3. return the unique value with max occurrence =INDEX(list_unique; MATCH(LARGE(list_number_occurence;1); list_number_occurence; 0))

You could try:

Formula in B1:

=LAMBDA(a,UNIQUE(SORT(FILTER({a,COUNTIF(a,a)},(COUNTIF(a,a)=MAX(COUNTIF(a,a)))+(COUNTIF(a,a)=MIN(COUNTIF(a,a)))),2,0)))(FILTER(A:A,A:A<>""))

Let's hope with the comming of LET() this gets a lot easier.