Combining multiple gradle zip tasks into a single one

I have a gradle task to zip the .yaml files into a zip folder, which looks like this:

task gradleTask1(type: Zip) {
    from 'src/test/resources/source_one/'
    include '**/*'
    archiveName 'file-collect.zip'
    destinationDir(file("${buildDir}/resources/test/staging/target_one"))
}

Similarly, I have other tasks that look the same, but the source and target directories are different.

task gradleTask2(type: Zip) {
    from 'src/test/resources/source_two/'
    include '**/*'
    archiveName 'file-collect.zip'
    destinationDir(file("${buildDir}/resources/test/staging/target_two"))
}

task gradleTask3(type: Zip) {
    from 'src/test/resources/source_three/'
    include '**/*'
    archiveName 'file-collect.zip'
    destinationDir(file("${buildDir}/resources/test/staging/target_three"))
}

And the main issue is I have to add dependency every time I add a new zip task as follows:

compileJava.finalizedBy gradleTask1

compileJava.finalizedBy gradleTask2

compileJava.finalizedBy gradleTask3

Is there any way I can achieve these steps dynamically? Can I have a single zip task (something like zipAll) and finally the task dependency can be

compileJava.finalizedBy zipAll

Consider the following (example here):

tasks.withType(Zip).all { task ->
    def taskName = task.name

    if (taskName ==~ /gradleTask.*/) {
        println "TRACER adding dependency on ${taskName}"
        compileJava.finalizedBy taskName
    }
}

This will dynamically find tasks of type Zip with name matching gradleTask* and add it to the list of tasks for compileJava.finalizedBy.

There is no zipAll task, but gradle compileJava will work as desired.