is it possible to write rules on instances rather than classes in drools?

I am trying to write something like this with drools but I am not sure how to go about it.

I have the following :

MyData d = new MyData();
MyData d1 = new MyData();
d.setValue(10);
d1.setValue(10);

and this is the rule I would like to implement :

rule "data d value equals 10 "
when
	d.getValue()==10;
then
doSmthg();
end

if I were to change the LHS to

$d: MyData(Value ==10) 

the doSmthg() would be executed twice.

So is there a way to write the rule only about one instance instead of all the instances of the MyData class??

PS: I need to insert both d and d1 in the kieSession because I have other rules that involve all the instances.

You need to target the specific instance in your rule. Or if both items are the same and you just want the rule to fire once for a given condition, you can insert a flag or other construct to keep it from firing multiple times.

For example, let's say that you have two MyData with value = 10. The one you do want to fire the rule also has a boolean flag latest = true.

So your working memory has:

MyData( value = 10, latest = true ) // we want to trigger the rule with this
MyData( value = 10, latest = false ) // and not this

Then we'd modify our rule to also check for the latest flag.

rule "Data value is 10, latest"
when
  $d: MyData( value == 10, latest == true )
then
  $d.doSmthg();
end

Alternatively if both objects are actually the same and there's nothing unique about them, and we just want to trigger based on the presence of a MyData with value 10, you have two ways to do this.

The first way is to use exists -- this just fires if there exists an instance in working memory that meets this criteria. As long as you never re-evaluate the rule by calling update, this should suit your needs. Note however that you have no reference to the object in this case.

rule "Any data value with 10 exists"
when
  exists( MyData(value == 10) )
then
  doSmthg(); // must be function or static import; cannot be instance method
end

If you do need to do work against the instance, you can't use exists and instead have to insert a flag or otherwise keep the rule from firing again. Easiest way is to insert something into working memory to act as a flag.

rule "Data value is 10, with flag"
when
  not( String(this == "DATA_10") ) // if flag does not exist in memory
  $d: MyData( value == 10 )
then
  $d.doSmthg();
  insert( "DATA_10" ); // insert flag
end

So to summarize, your options are:

1. Key off of a unique characteristic if possible
2. Use exists if you don't need an instance reference
3. Insert a flag or other flow control mechanism to keep the rule from firing a second time.