how do I change the colour of a row and column of the ellipses in response to the mouse being over one of the ellipses?

1. I've built this sketch on processing where it generates ellipses on the grid. I wanted to know how I would change the color of a row and column when the mouse hovers over it.

void setup()
{
  size(400,400);
  noStroke();
  fill(180,50, 50, 100);
}
 
void draw()
{
  background(255);
 
  for (int row=0; row<10; row = row+1)
  {
    for (int col=0; col<10; col = col+1)
    {
      ellipse(20 + col*40, 20 + row*40,30,30);
        if (mousePressed && (mouseButton == LEFT))
        fill (random (55));
         ellipse(20 + col*40, 20 + row*40,30,30);
      
    }
  }
}

Compute the center point coordinates of the ellipse:

int cY = 20 + row*40;
int cX = 20 + col*40;

The position of the mouse is stored in the built-in variables mouseX and mouseY.
The ellipses are arranged in a grid. Test whether either the x- or the y-coordinate of the mouse is in the area of ​​the grid that belongs to the ellipse. Set the color depending on the test result:

if ((mouseX > cX-20 && mouseX < cX+20) || mouseY > cY-20 && mouseY < cY+20) { 
    fill(255, 50, 50, 255);
} else {
    fill(180, 50, 50, 100);
}

Complete example:

void setup() {
    size(400,400);
    noStroke();
}
 
void draw() {
    background(255);
   
    for (int row=0; row < 10; row++) {
        int cY = 20 + row*40;
        for (int col=0; col < 10; col++) {
            int cX = 20 + col*40;
            
            if ((mouseX > cX-20 && mouseX < cX+20) || mouseY > cY-20 && mouseY < cY+20) { 
                fill(255, 50, 50, 255);
            } else {
                fill(180, 50, 50, 100);
            }
            ellipse(cX, cY, 30, 30);
        }
    }
}