XSTL/ XSL file: need to remove duplicates generically from the parent tag given that all the child key values are same for XML

I have been working on a problem for a long time. I need to remove duplicates from xml file based on the key value of the child tag. The parent tag "A" will always be known and will stay the same. The nested tags can have different names i.e., there could be "Name", "Location", "Name". If the data under 2 "Name" tags are duplicates of each other, one of the name tag along with its child nodes must get removed. This should only happen if all the child tag key values are same and not if only one or 2 or more tags are same but there exists some tags with different key value or same key and different value under the parent tag.

Example:

`<A>
  <Name>
  <c>1<c>
  <d>g</d>
  <e>h</e>
 </Name>
 <Location>
  <c>2<c>
  <d>g</d>
  <e>h</e>
 </Location>
 <Name>
  <c>1<c>
  <d>g</d>
  <e>h</e>
 </Name>
<A>`

Expected output:

`<A>
 <Name>
  <c>1<c>
  <d>g</d>
  <e>h</e>
 </Name>
 <Locaiton>
  <c>2<c>
  <d>g</d>
  <e>h</e>
 </Locaiton>
<A>`

I tried : this:

`<xsl:template match="@*|node()">
  <xsl:if test="not(node()) or not(preceding-sibling::node()[.=string(current())])">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:if>

</xsl:template>`

but what ended up happening was that the child tags with the same key values got removed as well and I was getting something like this:

`<A>
 <Name>
     <c>1<c>
     <d>g</d>
     <e>h</e>
</Name>
<Location>
    <c>2<c>

</Location>
<A>`

I'm looking for a generic way as I don't want to specify the tag values or keys in the file.

Thanks in advance :)!

In XSLT 3 using a composite key with for-each-group group-by might suffice:

  <xsl:template match="A">
      <xsl:copy>
          <xsl:for-each-group select="*" composite="yes" group-by="*">
              <xsl:apply-templates select="."/>
          </xsl:for-each-group>
      </xsl:copy>
  </xsl:template>

If the grandchildren also not to be sorted then you might need

      <xsl:for-each-group select="*" composite="yes" group-by="sort(*, (), function($c) { name($c) })">

instead of the simple group-by given above.

Both ways, as the base transformation, you need to set up the identity transformation by declaring <xsl:mode on-no-match="shallow-copy"/> as a child of xsl:stylesheet (or xsl:transform) in the XSLT.

But the problem is rather underspecified, it is not clear whether the names and order of child elements are simply unknown are always the same or whether there can be variations and how to handle them.

As an alternative, if you can have different elements as children of A but need to eliminate duplicates only for a specific one like B but for possible other elements then a key explicitly declared for B elements can help

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  expand-text="yes">

  <xsl:mode on-no-match="shallow-copy"/>
  
  <xsl:key name="B-group" match="A/B" use="sort(*, (), function($c) { name($c) })"/>

  <xsl:template match="B[not(. is key('B-group', sort(*, (), function($c) { name($c) }))[1])]"/>

</xsl:stylesheet>