How to publish a JAR with no source?

I've a multimodule Kotlin Gradle project:

data-cassandra
-- cassandra-autoconfigure
-- cassandra-starter

cassandra-autoconfigure has source code, the other two don't. cassandra-starter's purpose in life is to bring in cassandra-autoconfigure as api(project(":cassandra-autoconfigure")); this is a standard convention in Spring Boot. cassandra-starter has some test code, but nothing in src/main/kotlin.

Problem is, when I try to publish these projects, it's failing.

Artifact cassandra-starter-1.0.0-SNAPSHOT.jar wasn't produced by this build.

This is true and I can see > Task :cassandra-starter:jar SKIPPED. How do I force Gradle to build the jar with only META-INF in it?

data-cassandra/build.gradle.kts:

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    java
    kotlin("jvm") apply false
    `maven-publish`
}

allprojects {
    group = "mycompany.data"
    version = "1.0.0-SNAPSHOT"

    repositories {
        mavenCentral()
    }
}

subprojects {
    apply(plugin = "kotlin")
    apply(plugin = "maven-publish")

    tasks.withType<Test> {
        useJUnitPlatform()
    }

    tasks.withType<KotlinCompile> {
        kotlinOptions {
            freeCompilerArgs = listOf(
				"-Xjsr305=strict"
			)
            jvmTarget = "11"
        }
    }

    plugins.withType<JavaPlugin> {
        extensions.configure<JavaPluginExtension> {
            sourceCompatibility = JavaVersion.VERSION_11
            targetCompatibility = JavaVersion.VERSION_11
        }
        val springBootVersion: String by project
        dependencies {
            implementation(platform("org.springframework.boot:spring-boot-dependencies:$springBootVersion"))
            implementation("org.jetbrains.kotlin:kotlin-reflect")
            implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8")
            testImplementation("org.springframework.boot:spring-boot-starter-test") {
                exclude(group = "org.junit.vintage", module = "junit-vintage-engine")
                exclude(group = "com.vaadin.external.google", module = "android-json")
            }
        }
    }

    val isSnapshot = project.version.toString().toLowerCase().endsWith("snapshot")
    val artifactoryUrl = property("artifactoryUrl") as String

    extensions.configure<PublishingExtension> {
        publications {
            create<MavenPublication>("maven") {
                from(components["java"])
            }
            repositories {
                maven {
                    url = uri(artifactoryUrl + if (isSnapshot) "/libs-snapshot-local" else "/libs-release-local")
                    credentials {
                        username = property("artifactoryUsername") as String
                        password = property("artifactoryPassword") as String
                    }
                    if (!artifactoryUrl.startsWith("https")) {
                        isAllowInsecureProtocol = true
                    }
                }
            }
        }
    }
}

tasks.withType<PublishToMavenRepository> {
    doFirst {
        println("Publishing ${publication.groupId}:${publication.artifactId}:${publication.version} to ${repository.url}")
    }
}

cassandra-autoconfigure/build.gradle.kts

plugins {
	kotlin("jvm")
	kotlin("plugin.spring")
}

val springDataVersion: String by project
dependencies {
	implementation(platform("org.springframework.data:spring-data-releasetrain:$springDataVersion"))
	api("org.springframework.boot:spring-boot-starter-data-cassandra-reactive")
}

cassandra-starter/build.gradle.kts

plugins {
	id("org.springframework.boot")
	kotlin("jvm")
	kotlin("plugin.spring")
}

val cassandraUnitVersion: String by project
dependencies {
	api(project(":cassandra-autoconfigure"))
	testImplementation("org.cassandraunit:cassandra-unit:$cassandraUnitVersion") {
		exclude(group = "org.hibernate", module = "hibernate-validator")
	}
}

tasks.bootJar {
	enabled = false
}

Answering my own question, from Spring Boot docs:

> By default, when the bootJar or bootWar tasks are configured, the jar
> or war tasks are disabled. A project can be configured to build both
> an executable archive and a normal archive at the same time by
> enabling the jar or war task:

cassandra-starter/build.gradle.kts

tasks.jar {
	enabled = true
}

fixes the issue.